Interactividad estable del mundo anular con otros objetos del sistema solar

TL;DR: Sí, es posible el movimiento helicoidal alrededor de un mundo anular. Sin embargo, está lejos de ser uniforme a distancias mayores (≥ 0,04 AU).

Resumen de Resultados:

Para un mundo anular toroidal con masa$M_R = 3 M_\text{star} = 3M_\odot$, radio central$a = 1 \text{ AU}$y radio interior$b = 10^{-4} a \simeq 15000\text{ km}$(por lo tanto densidad$\rho \sim 8800\text{ kg/m}^3$, Comparar con$\rho_{\text{Fe}}\sim 7800\text{ kg/m}^3$), la relación entre la separación media del anillo central del ringworld y el período de tiempo viene dada por el siguiente gráfico:

$\lambda a$es la distancia desde el anillo central. Las ecuaciones se ajustan usando el valor promedio (cuadrado) de$\lambda$más de 1 año. Los valores de mediana (pentágono) y lanzamiento (círculo) de$\lambda$también se muestran. Las barras de error indican el valor mínimo y máximo de$\lambda$. Negro → sin estrella central, naranja →$M_{\text{star}} = M_{\odot}$.

La trayectoria es de hecho helicoidal.

Podemos ver la sección transversal proyectada a continuación. El centro del anillo está en$x=-1$(a escala de$a$, no mostrado), el anillo central del toro está en$x=0$. Está claro que las "distancias internas" son mayores que las "distancias externas" como cabría esperar ingenuamente. Como antes, negro → sin estrella central, naranja →$M_{\text{star}} = M_{\odot}$. El primer gráfico es translúcido, por lo que puede ver ambas secciones transversales al hacer zoom.

Física:

Para simplificar, considere una partícula puntual; si el satélite es demasiado grande (¿qué tan grande?) habría complicaciones debido al límite de Roche, etc. Reemplace el mundo del anillo (toro para el cálculo del volumen) con su anillo central para todos los demás cálculos. Deja que la partícula sea lanzada desde$(x,y,z)=((1-\lambda) a, 0,0)$. Sólo consideramos el régimen$0.01 \leq \lambda \leq 0.1$. El límite inferior evita que la partícula reconozca que el mundo del anillo se ha aproximado a un anillo y el límite superior evita que su órbita sea sustancialmente perturbada por la estrella.

Suponga inicialmente que la velocidad radial es cero. La velocidad tangencial para orbitar alrededor de la estrella (inicialmente$v_y$) debe ser aproximadamente$\sqrt{G M_{\text{star}}/((1-\lambda) a)}$. La velocidad orbital alrededor del mundo del anillo (inicialmente$v_z$) debe ser aproximadamente$\sqrt{g((1-\lambda) a,0,0) \lambda a}$dónde$g(x,y,z)$es la magnitud del campo gravitatorio neto (también conocido como aceleración de la gravedad) en función de la posición.

Estamos un poco atascados sin un número para$g((1-\lambda) a,0,0)$.

El potencial eléctrico de un anillo de carga.$Q$se da como (Ref. 1):

Es fácil obtener el potencial de un anillo gravitatorio sustituyendo$\epsilon_0 \rightarrow -1/(4\pi G)$y$Q\rightarrow M$en la ecuación. Uno puede tomar el gradiente (con un$-$firmar) y encuentre el campo numéricamente.

O uno podría ir unos pasos más allá y calcularlo todo. Usando la ecuación mostrada anteriormente para un valor de$M_R$(naranja en el gráfico), se puede extrapolar a otros valores de$M_R$usando$1/T\propto\sqrt{M_R}$(mientras$M_R$no es mucho más pequeño que$M_S$) como

Implementación (Mathematica):

(Todo está en unidades SI a menos que se indique lo contrario).

Primero establecemos las constantes. La integral elíptica para$V$anterior es algo desagradable y lleva un tiempo simplificarlo, así que lo simplifiqué una vez y reemplacé la definición con el resultado de la simplificación.

G = 6.674 10^-11;
EarthMass = 5.9722 10^24;
SolarMass = 333000 EarthMass;
RingMass = 3 SolarMass;
AU = 1.508 10^11;
a = 1 AU;
b = 10^-4 a;
day = 24*3600 // N;
year = 365.25 day;
\[Rho] = RingMass/((2 \[Pi] a) (\[Pi] b^2)) (* roughly 8800, Fe \[Rule] 7800 *) 
(* Math *)
VRing[r_, \[Phi]_, z_, 
   MR_] = -G MR/(2 \[Pi]) ((2 Sqrt[(
       a^2 + r^2 + z^2 - 2 a r Cos[\[Phi]])/((a - r)^2 + 
        z^2)] (EllipticF[\[Pi] - \[Phi]/2, -((
           4 a r)/((a - r)^2 + z^2))] + 
         EllipticF[\[Phi]/2, -((4 a r)/((a - r)^2 + z^2))]))/(Sqrt[
      a^2 + r^2 + z^2 - 2 a r Cos[\[Phi]]]));
VRingxyz[x_, y_, z_, MR_] = 
  TransformedField["Polar" -> "Cartesian", 
   VRing[r, \[Phi], z, MR], {r, \[Phi]} -> {x, y}];
Vtot[x_, y_, z_, MR_, MS_] = -G MS/Norm[{x, y, z}] + 
   VRingxyz[x, y, z, MR];
gRing[x_, y_, z_, MR_] = -Grad[VRingxyz[x, y, z, MR], {x, y, z}];
gtot[x_, y_, z_, MR_, 
   MS_] = -Grad[Vtot[x, y, z, MR, MS], {x, y, z}] /. 
   Abs[p_] Abs'[p_] -> p;
gtotmag[x_, y_, z_, MR_, MS_] = Norm[gtot[x, y, z, MR, MS]];

Hagamos una comprobación rápida de cordura y veamos si el campo gravitatorio es el esperado.

imgWidth = 2160;
plotAndExport[fname_, 
   plot_] := (Export[NotebookDirectory[] <> fname, 
    Rasterize[plot, ImageSize -> imgWidth]]; plot);
fieldPlotXLim = 1.5/Sqrt[2]; fieldPlotYLim = fieldPlotXLim;
splot = plotAndExport["field.png", #] &@
   Show[StreamPlot[
     Chop@(gtot[x1 a, y1 a, 0, RingMass, SolarMass][[1 ;; 2]])
     , {x1, -fieldPlotXLim, fieldPlotXLim}, {y1, -fieldPlotYLim, 
      fieldPlotYLim}
     , BaseStyle -> {FontSize -> 24}]];

Se ve bien. El primer gráfico muestra el "flujo" del campo (los tamaños de las flechas no son correctos). La magnitud del campo a lo largo de la$x$También se muestra el eje.

Ahora implementamos los solucionadores para la trayectoria de la partícula.

(* Trajectory solvers with initial conditions *)

xi[\[Lambda]_] := a (1 - \[Lambda]);
yi[\[Lambda]_] := 0.;
zi[\[Lambda]_] := 0.;
vxi[\[Lambda]_] := 0.;
vyi[\[Lambda]_] := Sqrt[G SolarMass/Abs[xi[\[Lambda]]]];
vzi[\[Lambda]_, MR_] := 
  Sqrt[Abs[a - xi[\[Lambda]]] Norm@
     gRing[xi[\[Lambda]], yi[\[Lambda]], zi[\[Lambda]], MR]];
ringSol[\[Lambda]_, MR_, time_] := NDSolve[
   Flatten@{Thread[{xs''[t], ys''[t], zs''[t]} == 
       gRing[xs[t], ys[t], zs[t], MR]],
     xs'[0] == vxi[\[Lambda]], ys'[0] == vyi[\[Lambda]], 
     zs'[0] == vzi[\[Lambda], MR], 
     xs[0] == xi[\[Lambda]], ys[0] == yi[\[Lambda]], 
     zs[0] == zi[\[Lambda]]},
   {xs, ys, zs}, {t, 0, time}];

xiFull[\[Lambda]_] := xi[\[Lambda]];
yiFull[\[Lambda]_] := yi[\[Lambda]];
ziFull[\[Lambda]_] := zi[\[Lambda]];
vxiFull[\[Lambda]_] := vxi[\[Lambda]];
vyiFull[\[Lambda]_, MS_] := Sqrt[G MS/Abs[xi[\[Lambda]]]];
vziFull[\[Lambda]_, MR_, MS_] := 
  Sqrt[Abs[a - xi[\[Lambda]]] Norm@
     gtot[xi[\[Lambda]], yi[\[Lambda]], zi[\[Lambda]], MR, MS]];
fullSol[\[Lambda]_, MR_, MS_, time_, \[Epsilon]_] := NDSolve[
   Flatten@{Thread[{xs''[t], ys''[t], zs''[t]} == 
       gtot[xs[t], ys[t], zs[t], MR, MS]]
     , xs'[0] == vxiFull[\[Lambda]], ys'[0] == vyiFull[\[Lambda], MS],
      zs'[0] == (1 + \[Epsilon]) vziFull[\[Lambda], MR, MS]
     , xs[0] == xiFull[\[Lambda]], ys[0] == yiFull[\[Lambda]], 
     zs[0] == ziFull[\[Lambda]]}
   , {xs, ys, zs}, {t, 0, time}
   ];

appendVelocities[solution_] := 
 Append[solution, {vx -> xs', vy -> ys', vz -> zs'} /. solution]

Necesitaremos un montón de funciones para analizar el período de tiempo.

(* Examining the period T of rotation about the ring *)
(* findPeriod and reconstruct copied from \
https://mathematica.stackexchange.com/a/38221/9332 *)

findPeriod[data_, threshold_] := 
 Module[{fs, s1, s = {}, i, a0f, af, pf, pos, fr, frpos, fdata, 
   fdatac, n, per}, n = Length[data];
  fs = Fourier[data];
  s1 = Drop[fs, -Floor[Length[fs]/2]];
  For[i = 1, i < Length[s1], i++, 
   If[Abs[fs][[i + 1]] > threshold, AppendTo[s, i + 1]]];
  a0f = Abs[fs[[1]]]/Sqrt[n];
  af = 2/Sqrt[n] Abs[fs][[s]];
  pf = Arg[fs][[s]];
  {a0f, Transpose[{s, af, pf}]}]
reconstruct[data_, fp_] := Module[{n}, n = Length[data];
   Show[ListLinePlot[data, PlotStyle -> Black], 
    Plot[fp[[1]] + 
      Sum[fp[[2, j, 2]] Cos[
         2 Pi (fp[[2, j, 1]] - 1)/n t - fp[[2, j, 3]]], {j, 1, 
        Length[fp[[2]]]}], {t, 0, n}, PlotStyle -> Red]]];
getOrbitPeriod[solution_, totalTime_, timeStep_] := Module[{data},
   data = 
    Flatten@Table[
      zs[t timeStep] /. solution, {t, 0, totalTime/timeStep}];
   (* Not strictly correct as there are many frequencies but good \
enough for first approximation *)

   totalTime/(timeStep Sort[
        findPeriod[data, 10^8][[2]], #1[[2]] > #2[[2]] &][[1, 1]])];

(* The period T is observed to be linear in \[Lambda] *)
\
\[Lambda]TFit[\[Lambda]list_, Tlist_] := 
  LinearModelFit[
   Transpose@{\[Lambda]list, Tlist}, \[Lambda], \[Lambda]];

setGraphFontSize = BaseStyle -> {FontSize -> 12};
graphLineWidth = 0.003;
graphMarkerLineWidth = 0.005;
graphMarkerSize = 6;
opacity = 0.5;
polygonMarker[color_, n_] := 
  Graphics[{EdgeForm[{Thickness -> graphMarkerLineWidth, color}], 
    FaceForm[None], Polygon[CirclePoints@n]}, 
   ImageSize -> graphMarkerSize];

coloredListPlot[x_, y_, color_, PM_] := 
  ListPlot[Transpose@{x, y}, PlotStyle -> color, PlotMarkers -> PM];
Needs["ErrorBarPlots`"]
\[Lambda]TFitGraph[{\[Lambda]list_, min\[Lambda]_, max\[Lambda]_, 
   mean\[Lambda]_, median\[Lambda]_}, Tlist_, color_] := 
 Module[{model = \[Lambda]TFit[mean\[Lambda], Tlist]},
  Show[
   Plot[Normal[model], {\[Lambda], 0.01, Max[mean\[Lambda]]}
    , PlotStyle -> {color, Dashed, Thickness -> graphLineWidth}, 
    AxesLabel -> {"\[Lambda]", "T (days)"}
    , PlotLegends -> SwatchLegend[{color}, {Normal[model]}]
    , Evaluate@setGraphFontSize, 
    PlotRange -> {{0, Automatic}, {0, Automatic}}]
   , ErrorListPlot[
    (({{#1, #4}, ErrorBar[{#2 - #1, #3 - #1}, {0, 0}]} &) @@ # &) /@ 
     Transpose@{mean\[Lambda], min\[Lambda], max\[Lambda], Tlist}
    , PlotStyle -> {color, Thickness -> graphLineWidth}, 
    PlotMarkers -> polygonMarker[color, 4]]
   , coloredListPlot[\[Lambda]list, Tlist, 
    color, {Automatic, graphMarkerSize}]
   , coloredListPlot[median\[Lambda], Tlist, color, 
    polygonMarker[color, 5]]
   ]]

Finalmente, ejecutamos los solucionadores y vemos los datos.

(* Actually run simulations *)

ringSolutionTime = year;
ring\[Lambda]list = Range[0.01, 0.1, 0.01];

AbsoluteTiming[
  ringSolutions = 
   Flatten@appendVelocities@ringSol[#, RingMass, ringSolutionTime] & /@
     ring\[Lambda]list
  ][[1]]

ringPeriods = 
  getOrbitPeriod[#, ringSolutionTime, day] & /@ ringSolutions;
{ringMaxDist, ringMinDist, ringMeanDist, ringMedianDist} = 
  Transpose[distCalc[#, ringSolutionTime, day/24] & /@ ringSolutions];

TableForm@{ring\[Lambda]list, ringMaxDist, ringMinDist, 
  ringMeanDist, ringMedianDist}

fullSolutionTime = year;
full\[Lambda]list = ring\[Lambda]list + 0.005;
AbsoluteTiming[
  fullSolutions = 
   Flatten@appendVelocities@
       fullSol[#, RingMass, SolarMass, fullSolutionTime, 0] & /@ 
    full\[Lambda]list
  ][[1]]

fullPeriods = getOrbitPeriod[#, fullSolutionTime, day] & /@ fullSolutions;
{fullMaxDist, fullMinDist, fullMeanDist, fullMedianDist} = 
  Transpose[distCalc[#, fullSolutionTime, day/24] & /@ fullSolutions];

TableForm@{full\[Lambda]list, fullMaxDist, fullMinDist, 
  fullMeanDist, fullMedianDist}

Haciendo el$T$contra$\lambda$trazar y ver la trayectoria (gráficos en resumen).

plotAndExport["Tvl.png", #] &@
 Show[
  \[Lambda]TFitGraph[{ring\[Lambda]list, ringMinDist, ringMaxDist, 
    ringMeanDist, ringMedianDist}, ringPeriods, Black]
  , \[Lambda]TFitGraph[{full\[Lambda]list, fullMinDist, fullMaxDist, 
    fullMeanDist, fullMedianDist}, fullPeriods, Orange]
  , PlotRange -> {{0, Automatic}, {0, Automatic}}
  ]
plotAndExport["traj.png", #] &@
 Show[GraphicsGrid[{{
     trajectory[full\[Lambda]list[[1]], fullSolutions[[1]], 
      fullSolutionTime/7]
     , trajectory[full\[Lambda]list[[1]], fullSolutions[[1]], 
      fullSolutionTime]
     }}]]

Referencias:

1. http://physics.oregonstate.edu/portfolios/Activities/EMActivities/ElectricPotentialRing/RingVSolutions070701.pdf

Hay aspectos de esta pregunta que hacen que sea bastante difícil de responder. La demostración física de gotas cargadas que giran en espiral alrededor de una aguja de tejer cargada da una idea razonable del concepto que está tratando de considerar. Cualquier respuesta tendrá que sustituir un campo gravitatorio por el campo electrostático de las gotas y la aguja de tejer. Esto puede no ser tan sencillo. Cualquiera que sepa que estoy equivocado acerca de esta proposición, por favor salte y demuélvala.

Se sugiere que el mundo del anillo deberá ser masivo para tener un planeta similar a la Tierra en una órbita espiral alrededor del mundo del anillo. Si bien se puede suponer que el planeta similar a la Tierra tiene una masa equivalente a la de la Tierra, esa es la parte fácil. Ahora veamos los factores desconocidos en este modelo.

Se desconoce la masa del mundo del anillo. Se desconoce la velocidad del planeta similar a la Tierra. La masa del mundo del anillo determinará la fuerza gravitacional que actúa sobre el planeta para mantenerlo en órbita alrededor del mundo del anillo. Mientras que la velocidad del planeta determinará su probabilidad de mantener su órbita alrededor del mundo del anillo.

Esto sugiere que el mundo del anillo deberá ser extremadamente masivo. Muy probablemente, la masa del mundo anillo será del orden de una masa solar. Es decir una masa similar a la del Sol. En cuyo caso, el mundo del anillo deberá estar hecho de materia ultradensa del tipo propuesto por Robert L. Forward en su artículo especulativo "Far out Physics" ( Analog , agosto de 1975, páginas 147-166).

El planeta tendrá que moverse a gran velocidad. Esto es alto en comparación con las órbitas planetarias normales. La Tierra gira alrededor del Sol con una velocidad de 30 km/s. Sin embargo, no es fácil idear una forma de conceptualizar la relación entre la masa del mundo del anillo y la velocidad del planeta en una órbita espiral. Esto depende de la distribución de la masa a lo largo del mundo del anillo y de la fuerza que ejerce sobre un planeta de masa terrestre para que el planeta pueda mantenerse en una órbita espiral alrededor del mundo del anillo.

Una cosa que es preocupante es el hecho de que todas las gotas cargadas terminan cayendo sobre la aguja de tejer cargada. Si el mismo comportamiento se aplica a un planeta en una órbita espiral alrededor de un mundo anular masivo, entonces el planeta terminará chocando contra la superficie ultradensa del mundo anular. Si bien esto es emocionante y dramático, no será una buena noticia para ningún habitante del planeta.

Cualquier respuesta que pueda venir con una solución al problema propuesto por la pregunta necesitará idear un modelo que describa la relación gravitatoria y de velocidad entre el mundo del anillo y el planeta en una órbita espiral para escalar el tiempo de la órbita del planeta y, posiblemente, la estabilidad de este sistema. Actualmente, los factores desconocidos dificultan la determinación de una respuesta. Esta respuesta ha explorado los factores limitantes del problema, pero no ha podido proponer una solución a la pregunta del OP.

APÉNDICE:

El problema principal es la forma del campo gravitatorio de un mundo anular masivo. Con planetas y estrellas, el campo gravitatorio se concentra alrededor de una fuente puntual. El campo del mundo del anillo tiene una fuente extendida. El planeta podría tener dos componentes de velocidad. Uno la velocidad orbital alrededor de la estrella, el otro una velocidad orbital alrededor del mundo del anillo. Eso produciría la órbita espiral.

Ahora bien, esta consideración sugiere una posible solución. Suponga que la masa del mundo anular es igual a la del planeta de masa terrestre en una franja de 12 742 kilómetros de ancho. Este ancho se elige porque es el diámetro de un planeta similar a la Tierra. Esto da una aproximación razonable para el campo gravitacional mínimo del mundo anular masivo para mantener un planeta de la masa de la Tierra en órbita alrededor de él. Suponiendo que tiene una velocidad orbital de 8 km/s, ya que esta es la velocidad orbital necesaria para mantener un satélite en órbita alrededor de un planeta similar a la Tierra (en este caso, la franja de un mundo anular).

El planeta que orbita el mundo del anillo tendrá una velocidad orbital heliocéntrica de 30 km/s, que es exactamente la misma que la del planeta Tierra, y esta es solo una componente de la velocidad del planeta. El otro componente de velocidad mantiene al planeta circulando alrededor del mundo del anillo. Las velocidades combinadas dan como resultado una órbita espiral alrededor del mundo del anillo.

El OP puede conectar cualquier dimensión del mundo del anillo para establecer el tamaño de la órbita alrededor del mundo del anillo.

Un cálculo rápido indica que la masa del mundo del anillo será de 73.966,237 masas terrestres (donde 1 UA equivale a 150.000.000 kilómetros). Simplemente divida la circunferencia del mundo del anillo por 12 742 porque hemos asumido que cada franja de 12 742 kilómetros tiene una masa terrestre.

La órbita del planeta alrededor del mundo del anillo será una órbita alta. Posiblemente, algo así como una órbita de cuarenta y ocho horas que mantendrá al planeta lejos del mundo del anillo. Esto debería mantener el planeta seguro. Además, el ringworld tendrá que tener un ancho estrecho. Por ejemplo, unos 12.000 km, así es, más o menos el diámetro de la Tierra. Nuevamente, esto es para hacer que la órbita espiral del planeta sea segura. El radio de la órbita desde el mundo del anillo es de 220.015,79 km. De improviso, no es seguro si esta órbita es viable. Nota: esto supone que la velocidad orbital es de 8 km/s.