Responda correos electrónicos automáticamente con Mail & AppleScript & Automator

Hay docenas de números de conferencias telefónicas almacenados en mi computadora. Estos números son todos números, como 40027683, ningún otro carácter. Estos números se guardan en un archivo txt.ingrese la descripción de la imagen aquí

Algunos de mis usuarios pueden necesitar un número cuando intentan realizar una llamada de conferencia con sus clientes. Entonces, cada vez que los usuarios soliciten un número de llamada de conferencia a través de correos electrónicos, responderé con un número.

¿Hay alguna manera de responder a esos correos que requieren números de llamada automáticamente? Me gustaría probar Mail, AppleScript y Automator.

Me gustaría pedirle a Mail que ejecute AppleScript cuando se reciba un nuevo correo electrónico (el asunto o el contenido del mensaje contiene la palabra clave "concall"), aquí hay un ejemplo:

ingrese la descripción de la imagen aquí

El AppleScript que escribí se ejecutará para invocar el primer número del archivo txt. La próxima vez que llegue otro mensaje, Mail ejecutará AppleScript para invocar el segundo número del archivo txt. ¿Hay alguna manera de hacer que suceda?

Cualquier sugerencia sería muy apreciada.

¿Podría incluir el AppleScript que tiene hasta ahora en su pregunta? Puede poner los códigos usados ​​en un archivo diferente. Así que cuando recibas otro correo. Simplemente vuelve a tomar el primer código.
Lo siento, no lo dejé claro. No tengo ningún código ahora. Porque no sé cómo invocar los números del archivo txt o cómo invocar el número dentro del script. Lo que quiero que suceda es: cuando llegue un nuevo correo electrónico (con el asunto o el contenido: concall), Mail ejecutará AppleScript para invocar la primera línea del archivo txt. Luego llegó otro correo, Mail ejecutará AppleScript para invocar la segunda línea del archivo txt.

Respuestas (1)

Puedes hacerlo así:

property the_numbers : {10000, 20000, 30000}
using terms from application "Mail"
    on perform mail action with messages theMessages for rule theRule
        repeat with i from 1 to count of theMessages
            tell application "Mail"
                set the_sender to sender of item i of theMessages
                set the_subject to subject of item i of theMessages
                set the_counter to item 1 of the_numbers
                -- make the outgoing message (the reply)
                set the_reply to make new outgoing message with properties ¬
                    {subject:"Re: " & the_subject, content:"Use this number-- " & the_counter}
                tell the_reply
                    make new to recipient at end of to recipients with properties {address:the_sender}
                end tell
                send the_reply
            end tell
            -- this is the step that deletes item 1 from the list 
            set the_numbers to items 2 thru -1 of the_numbers
        end repeat
    end perform mail action with messages
end using terms from

Esto funciona, pero tendrá que trabajar un poco para convertir su lista de números en una lista de AppleScript. Los colocará en la parte superior, separados por comas, reemplazando mis 10000, 20000, 30000.

Llamo a la lista de números "the_numbers". Al llamarlo una propiedad, guardamos el valor de the_numbers de una ejecución a otra. Si tuviera que usar mi secuencia de comandos tal cual en lugar de su "Sin título 3" en la regla que configuró, la primera vez que se llame a la secuencia de comandos, funcionará con {10000, 20000, 30000}. La próxima vez que se ejecute, la lista será {20000, 30000}. La próxima vez que se ejecute, será {30000}. También será {30000} para todas las ejecuciones posteriores. Supongo/espero que tenga una lista muy larga de números y que no se le acabe.

Un guión mejor le permitiría saber que la lista de números se redujo hasta el último.

Muchas gracias, cristiano. Su guión funciona para mí. no se como agradecerte Quiero comprarte una docena de cerveza. ¿Puedo pagar 10$ por tu guión? Por favor, déjame cómo te transfiero el dinero.
De nada. Saber que te ayudé es muy satisfactorio y completamente suficiente. Puedes consultar mi perfil para obtener más información sobre mí.
Responda correos electrónicos automáticamente con Mail & AppleScript & Automator
RespuestasAquíPolítica de privacidad1y, 0v