Error en la barra de progreso de AppleScript: ¿Cómo evitar que el diálogo de progreso se prolongue?

Funciona para mí en la última versión de macOS Big Sur

ACTUALIZAR

MEJOR SOLUCIÓN

Si coloca el display dialogcomando dentro de un System Events tell blockluego envuelva el ignoring application responsescomando alrededor de ese display dialogcomando, progress indicatorcompletará su tarea sin esperar a display dialogque se cierre la ventana.

El ignoring application responsescomando solo funcionará si se coloca dentro de la aplicacióntell block

set n to 50

set progress total steps to n
set progress description to "Script Progress"
set progress additional description to "Additional description"

repeat with i from 1 to n
    delay 0.1
    set progress completed steps to i
end repeat

tell application "System Events"
    activate
    ignoring application responses
        display dialog "The progress dialog should be gone at this point."
    end ignoring
end tell

SOLUCIÓN ANTIGUA 1

set n to 5

set progress total steps to n
set progress description to "Script Progress"
set progress additional description to "Additional description"

repeat with i from 1 to n
    delay 0.1
    set progress completed steps to i
end repeat
return
quit

on quit
    activate
    display dialog "The progress dialog should be gone at this point."
    continue quit -- allows the script to quit
end quit

Aquí hay una forma de ejecutar algunos bucles repetidos antes de que se cierre el script.

set n to 5

set progress total steps to n
set progress description to "Script Progress"
set progress additional description to "Additional description"

repeat with i from 1 to n
    delay 0.1
    set progress completed steps to i
end repeat
return
quit

on quit
    activate
    display dialog "The progress dialog should be gone at this point."
    repeat 5 times
        my get_my_IP()
        my screenCaptureToDesktop()
        delay 1
    end repeat
    continue quit -- allows the script to quit
end quit


on get_my_IP()
    activate
    tell current application to display dialog (do shell script "curl ifconfig.co") with icon 2 buttons "OK" default button 1 with title "Your Current IP Address Is.." giving up after 5 -- "curl ifconfig.io"    -- alternate
end get_my_IP

on screenCaptureToDesktop()
    do shell script "/usr/sbin/screencapture \"" & ¬
        POSIX path of (path to desktop as string) & ¬
        "Screen Shot " & (current date) & ".png\""
end screenCaptureToDesktop

SOLUCIÓN ANTIGUA 2

Trabajando en uno de mis propios proyectos, tuve uno de esos "¡EUREKA!" momentos Aquí hay un enfoque completamente diferente a mi código en la SOLUCIÓN 1. El enfoque aquí fue envolver la mayor parte de mi código en objetos de script o controladores, luego llamar a esos objetos según sea necesario. En esta solución, guardé este script como una aplicación abierta, con controladores explícitos de ejecución e inactividad. Parte del código se ejecuta cuando se inicia la aplicación, pero la mayoría de los comandos en realidad suceden dentro del controlador inactivo.

Creo que esta solución promete más que la SOLUCIÓN 1.

global allFiles, thisFile, theFileCount, ProgressBar, mainFolder, backupFolder, theDate

on run
    run ProgressBar
end run

on idle
    delay 0.2
    activate
    set theButton to button returned of (display dialog ¬
        "The progress dialog should be gone at this point." buttons {"QUIT", "CONTINUE"} ¬
        default button ¬
        "CONTINUE" with title ¬
        "BACKUP UTILITY" with icon 0 ¬
        giving up after 10)
    if theButton = "QUIT" then
        quit
    else if theButton = "" then
        quit
    else if theButton = "CONTINUE" then
        try
            run ProgressBar
        end try
    end if
    return 1
end idle

on quit
    --  Executed when the script quits
    continue quit -- allows the script to quit
end quit

script ProgressBar
    set mainFolder to choose folder with prompt ¬
        "PLEASE CHOOSE YOUR SOURCE FOLDER TO BACKUP"
    set backupFolder to choose folder with prompt ¬
        "PLEASE CHOOSE YOUR BACKUP DESTINATION FOLDER"
    set theDate to (current date) - (14 * days)
    
    tell application "Finder"
        set allFiles to entire contents of folder mainFolder as alias list
    end tell
    
    set theFileCount to count of allFiles
    
    set progress total steps to theFileCount
    set progress completed steps to 0
    set progress description to "Processing Files..."
    set progress additional description to "Preparing to process."
    
    repeat with theName from 1 to number of items in allFiles
        set this_item to item theName of allFiles
        tell application "Finder"
            duplicate this_item to backupFolder ¬
                with replacing
        end tell
        set progress additional description to ¬
            "Duplicating File " & theName & " of " & theFileCount & ¬
            " to folder " & backupFolder
        set progress completed steps to theName
    end repeat
    
    -- Reset the progress information
    set progress total steps to 0
    set progress completed steps to 0
    set progress description to ""
    set progress additional description to ""
end script