De acuerdo, eliminé el original y la primera edición porque editaste tu pregunta original hasta el punto en que es más fácil escribir una nueva respuesta.

Dado que su pregunta original mostraba la siguiente línea de código , como ejemplo de cómo se puede configurar la variable, la incluiré para decir lo siguiente.

Si el varTextha sido establecido por ejemplo:

set varText to (return & "This is sentence 1." & return & "This is sentence 2." & return & "This is sentence 3." & return & "This is sentence 4.")

• En cuál returnes x0Dvs. el uso más apropiado de linefeed( x0A) en su lugar, en un caso donde la variable son datos y no un mensaje descartable.

O:

set varText to "
This is sentence 1.
This is sentence 2.
This is sentence 3.
This is sentence 4."

• En el que cada una de estas líneas en realidad termina con un linefeed( x0A) como debería ser en una Mac.

El do shell script comando tiene un error , ya que se convierte x0Adespués x0Dde lo que se devuelve desde la línea de comandos con las x0Aterminaciones esperadas devueltas. Confirmé esto porque si uso lo siguiente:

set varText to "
This is sentence 1.
This is sentence 2.
This is sentence 3.
This is sentence 4."

set varText to do shell script "sed  -e '1d;3d' <<< " & quoted form of varText & " | tee $HOME/Desktop/outfile"

Luego outfilecontiene terminaciones linefeed( x0A), por lo que se devuelve lo mismo do shell script, pero luego convierte erróneamente las x0Aterminaciones de línea en x0Dterminaciones que luego pueden manejarse de la siguiente manera:

Por lo tanto, para acomodar el error , siempre asegúrese de que el contenido de la variable pasada y devuelta contenga x0Afinales de línea utilizando el siguiente códigohandler de ejemplo .

Lo siguiente asume que varTextya ha sido configurado por cualquiera de los métodos descritos anteriormente.

on ensureLinesEndWith0A(varText)
    set varText to paragraphs of varText
    set oldTID to AppleScript's text item delimiters
    set AppleScript's text item delimiters to linefeed
    set varText to varText as string
    set AppleScript's text item delimiters to oldTID
    return varText
end ensureLinesEndWith0A

set varText to ensureLinesEndWith0A(varText)
set varText to do shell script "sed  -e '1d;3d' <<< " & quoted form of varText
set varText to ensureLinesEndWith0A(varText)

Luego, podría usar lo siguiente nuevamente para eliminar más líneas de varText:

set varText to ensureLinesEndWith0A(varText)
set varText to do shell script "sed  -e '1d;3d' <<< " & quoted form of varText
set varText to ensureLinesEndWith0A(varText)

La siguiente imagen muestra un ejemplo de llamar al do shell script " sed ..." comando dos veces.

Ejemplo:

set varText to "
This is sentence 1.
This is sentence 2.
This is sentence 3.
This is sentence 4."

set varText to do shell script "sed -e '1d;3d' <<< " & quoted form of varText

Devoluciones:

"This is sentence 1.
This is sentence 3.
This is sentence 4."

Actualización: como resultado de un descubrimiento mencionado en la Edición: de ¿Cómo eliminar una línea específica de un párrafo basado en "retorno" en AppleScript? , permítanme hacer la siguiente declaración:

NOTA: Desafortunadamente, lo que se devuelve en este caso tiene caracteres de retorno de carro (x0D) en lugar de los caracteres de nueva línea esperados (x0A) y, en mi opinión, ¡es un error!

Es un error porque: el do shell script "sed ..." comando cuando se ejecuta en la Terminal con eso varTextregresa con \n(x0A) no \r(x0D) como se supone que debe hacerlo. Incluso el do shell script "sed ..." comando compilado en Script Editor todavía tiene \n(x0A) no \r(x0D), sin embargo, por qué se devuelve con \r(x0D) la intención de lo esperado \n(x0A) es un misterio para mí en este momento y lo consideraré un AppleScript. error ya que no refleja el comportamiento esperado del mismo cuando se ejecuta en Terminal.

Entonces, para tener en cuenta el error en los resultados del do shell script "sed ..." comando , así es como lo manejaría. Después del do shell script "sed ..." comando, use las siguientes líneas de código :

set newLine to "\n"
set varText to paragraphs of varText
set oldTID to AppleScript's text item delimiters
set AppleScript's text item delimiters to newLine
set varText to varText as string
set AppleScript's text item delimiters to oldTID

Ahora, lo que se devuelve contiene caracteres de nueva línea (x0A) , ya que debería comenzar si no hubiera este error, no los caracteres de retorno de carro (x0D) .

Nota: cuando se compila, la set newLine to "\n"línea de código se mostrará a continuación:

set newLine to "
"

Dividamos este script en partes más pequeñas y luego juntémoslo todo en un AppleScript.

Este enfoque está escrito completamente en AppleScript y no requiere herramientas externas. El uso de herramientas externas, como perlo sed, probablemente resulte en soluciones mucho más breves, pero ha mencionado en otras preguntas que desea aprender AppleScript.

1. Dividir con delimitadores

Puede usar el comportamiento de los delimitadores de AppleScript para dividir una cadena . Puede cambiar el delimitador como desee a return, linefeedo incluso caracteres como =:

 -- http://macscripter.net/viewtopic.php?id=24473
 to split(someText, delimiter)
     set AppleScript's text item delimiters to delimiter
     set someText to someText's text items
     set AppleScript's text item delimiters to {""} --> restore delimiters to default value
     return someText
 end split

 set myText to (return & "This is sentence 1." & return & "This is sentence 2." & return & "This is sentence 3." & return & "This is sentence 4.")
 set myLines to split(myText, return)

2. Lista de filtros

Con la lista devuelta, puede filtrar los elementos no deseados mediante un bucle:

 -- http://macscripter.net/viewtopic.php?id=24525
 set indexesToDelete to {1, 4}
 set cleanList to {}

 repeat with i from 1 to count myLines
     if i is not in indexesToDelete then set cleanList's end to myLines's item i
 end repeat

3. Combina los artículos

La lista filtrada de oraciones se puede volver a combinar usando otro bucle:

-- Combine the filtered list into a string
set myResult to ""
repeat with i from 1 to count cleanList
    if myResult is "" then
        set myResult to cleanList's item i
    else
        set myResult to myResult & return & cleanList's item i
    end if
end repeat

Totalmente AppleScript

La combinación de estos fragmentos da como resultado el siguiente código:

-- Get the text to work with
set myText to (return & "This is sentence 1." & return & "This is sentence 2." & return & "This is sentence 3." & return & "This is sentence 4.")

-- Split the text into lines based on 'return' delimiter
set myLines to split(myText, return)

-- Filter out indexes 1 and 4 using a loop
set indexesToDelete to {1, 4}
set cleanList to {}
repeat with i from 1 to count myLines
    if i is not in indexesToDelete then set cleanList's end to myLines's item i
end repeat

-- Combine the filtered list into a string
set myResult to ""
repeat with i from 1 to count cleanList
    if myResult is "" then
        set myResult to cleanList's item i
    else
        set myResult to myResult & return & cleanList's item i
    end if
end repeat

-- Final string
myResult

to split(someText, delimiter)
    set AppleScript's text item delimiters to delimiter
    set someText to someText's text items
    set AppleScript's text item delimiters to {""} --> restore delimiters to default value
    return someText
end split

La secuencia de comandos anterior podría reducirse combinando el filtro y los bucles de recombinación. Las he dejado como tareas separadas para demostrar mejor sus roles.