Necesito un programa para hacer esto:
Básicamente, es solo un archivo program.exe que hace lo siguiente:
Es algo similar a Desktop Coral en términos de función. Otros programas similares serían stardocks
Pero en el sentido de que la caja se verá así
Necesito esto para poder hacer bordes alrededor de make screencast/.gif antes de hacerlos
EDITAR: tengo la intención de ejecutar un script de autohotkey para que esta ventana siempre esté en la parte superior
Modifiqué un script de autohotkey existente AutoHotKey script
b:=10 ; border in px . This is black border
t=false ; variables are set by default to false, this line not needed but added for clarity
;----------------
; This Initializes the window
;----------------
Gui,+Resize ; window resizable (drag)
Gui, Color, EEAA99 ; Initializes Color so not-everything transparent
Gui +LastFound ; Makes GUI the same background color as your regular window GUI apps
WinSet, TransColor, EEAA99 ; Sets transparency
Gui,Show,w500 h500 ; This sets width and height
return ; sends input
;------------
; Below is HotKey
;------------
F1::
t:=!t ; T is false default, changes to true upon first F1 push
if t { ; makes the "black border" unmovable window
Gui, -Caption +ToolWindow +LastFound -Resize +AlwaysOnTop ; "ToolWindow: Provides a narrower title bar but the window will have no taskbar button" -Caption "removes border and title bar",
Gui, Color, Black ; This sets color of border, causes temporary "black screen flash"
WinGetPos,,,w,h
q:=w-b, z:=h-b ; precalculates border
WinSet, Region, 0-0 %w%-0 %w%-%h% 0-%h% 0-0 %b%-%b% %q%-%b% %q%-%z% %b%-%z% %b%-%b% ; Creates "black border"
}
else { ; This secion resets to default
Gui, +Caption -ToolWindow +LastFound +Resize -AlwaysOnTop
Gui, Color, EEAA99 ;
Gui +LastFound ; Make the GUI window the last found window for use by the line below.
WinSet, TransColor, EEAA99 ;
WinSet,Region
}
return
Con él, puedo presionar F1para bloquear un borde que no se puede mover a menos que se presione F1 nuevamente (también se encuentra en la parte superior de la mayoría de las ventanas). Presiona F1de nuevo y podrás mover el borde libremente. Hice la ventana posicional transparente para que pueda ver lo que verá antes de tiempo.
Agregué muchas anotaciones en mi script. Aunque no hice el original aquí en la publicación de reddit
Puede usar esta función AutoHotKey para hacer gifs rápidos de screencast, bordes preanotados en capturas de pantalla también