¿Puede AppleScript buscar profundamente el archivo más grande contenido debajo de una carpeta?

Existen varios métodos para realizar esta tarea, cada uno con ventajas y desventajas. Los métodos de shell son rápidos , pero no siempre devuelven información actualizada . La interfaz Finder de AppleScript no es tan lenta como pensé que sería, pero solo devuelve valores viables para los tamaños de archivo que se han almacenado en caché, de lo contrario, "valor faltante" para el resto. System Events suele ser la aplicación de administración de archivos AppleScript preferida, ya que es rápida en la recuperación, pero se ralentiza al acceder a los atributos del archivo. Tampoco puede hacer una enumeración profunda de directorios como Finder (aunque se puede implementar manualmente).

Decidí usar el puente de secuencias de comandos de Objective-C para escribir un AppleScript que es súper rápido y totalmente capaz de descender a las subcarpetas de un directorio. En general, es el mejor método, pero tiene el inconveniente de que tu profesor puede sospechar un poco.

# Loads the Foundation framework into the script so that we can access its
# methods and constants
use framework "Foundation"

# Declare properties that belong to the Foundation framework for easier
# referencing within the script
property this : a reference to current application
property NSArray : a reference to NSArray of this
property NSDirectoryEnumerationSkipsHiddenFiles : a reference to 4
property NSDirectoryEnumerationSkipsPackageDescendants : a reference to 2
property NSFileManager : a reference to NSFileManager of this
property NSSortDescriptor : a reference to NSSortDescriptor of this
property NSString : a reference to NSString of this
property NSURL : a reference to NSURL of this
property NSURLFileSizeKey : a reference to NSURLFileSizeKey of this
property NSURLNameKey : a reference to NSURLNameKey of this
property NSURLPathKey : a reference to NSURLPathKey of this

# Call the handler defined below.  This is where the script does the actual
# retrieving of the files and filesizes
get my contentsOfDirectory:"~/Downloads"

# If we stopped the script at the line above, you'd see the entire contents of 
# the directory subtree listed with file paths and filesizes, ordered in 
# descending order by filesize.  However, you only want the largest file, so
# we pick out the first item in the list.
return item 1 of the result

--------------------------------------------------------------------------------
# This is an AppleScript handler declaration
on contentsOfDirectory:dir
    local dir # This tells the handler that the variable passed as the
    # parameter is limited in scope to this handler

    # Obtain a reference to the default file manager of the filesystem
    set FileManager to NSFileManager's defaultManager()

    # This is where retrieve the contents of the directory, recursing
    # into any subfolders.  The options declared tell the method to skip
    # hidden files and not to look inside file packages, such as 
    # applications or library files.  I've declared a list of keys that
    # pre-fetch file attributes during this retrieval, making it faster
    # to access their data later: filename, full path, and file size.
    set fs to FileManager's enumeratorAtURL:(NSURL's ¬
        fileURLWithPath:((NSString's stringWithString:dir)'s ¬
            stringByStandardizingPath())) ¬
        includingPropertiesForKeys:[¬
        NSURLPathKey, ¬
        NSURLNameKey, ¬
        NSURLFileSizeKey] ¬
        options:(NSDirectoryEnumerationSkipsHiddenFiles + ¬
        NSDirectoryEnumerationSkipsPackageDescendants) ¬
        errorHandler:(missing value)

    # I created the script object just to speed up the process of
    # appending new items to the empty list it contains.
    script |files|
        property list : {}
    end script

    # This is the repeat loop that we use to enumerate the contents
    # of the directory tree that we retrieved above
    repeat
        # This allows us to access each item in the enumerator one
        # by one.
        set f to fs's nextObject()

        # Once the list has been exhausted, the value returned above
        # will be a "missing value", signifying that there are no more
        # files to enumerate.  Therefore, we can exit the loop.
        if f = missing value then exit repeat

        # Here, we retrieve the values of file attributes denoted
        # by the keys I declared earlier.  I'm picking out the path
        # and the filesize as per your needs.
        f's resourceValuesForKeys:[NSURLPathKey, NSURLFileSizeKey] ¬
            |error|:(missing value)

        # The above command returns a record containing the two
        # file attributes.  This record gets appended to the list
        # stored in the script object above.
        set end of list of |files| to the result as record
    end repeat

    # The list in the script object is an AppleScript list object.  For
    # the next part, I need a cocoa list object (NSArray).
    set L to item 1 of (NSArray's arrayWithObject:(list of |files|))

    # This defines a sort descriptor which is used to sort the array.
    # I'm telling it to use the filesize key to sort the array by 
    # filesize, which will let us grab the largest file easily.
    set descriptor to NSSortDescriptor's alloc()'s ¬
        initWithKey:"NSURLFileSizeKey" ascending:no

    # Sort the list.
    L's sortedArrayUsingDescriptors:[descriptor]

    # Return the result.
    result as list
end contentsOfDirectory:

Esto se ofrece como una alternativa al código AppleScript Objective-C utilizado en la otra respuesta y está más en la línea del código AppleScript estándar que se muestra en el OP. Tenga en cuenta que el crédito por esta respuesta es para el autor de la otra respuesta, CJK, ya que se deriva de los comentarios ahora eliminados que hicimos entre nosotros en su respuesta original. Además, considero que su respuesta, a pesar de la complejidad, es superior en rendimiento a lo que se ofrece aquí.

Cuando se ejecuta este script, el usuario elige una carpeta y el resultado final, el nombre de ruta de los archivos más grandes dentro de la carpeta elegida, incluidas sus subcarpetas, se muestra en un cuadro de diálogo.

Ejemplo de código AppleScript :

set chosenFolder to quoted form of POSIX path of ¬
    (text items 1 thru -2 of ((choose folder) as text) as text)

set theLargestFilePathname to ¬
    (do shell script "find " & chosenFolder & ¬
        " -type f -ls | sort -nrk7 | awk '{for(i=11; i<=NF; ++i) printf $i\"\"FS; exit}'")

display dialog "The largest file within the chosen folder, and its subfolders, is:" & ¬
    linefeed & linefeed & theLargestFilePathname buttons {"OK"} default button 1 ¬
    -- giving up after 3        # Remove the '--' at the front of this line to enable this.

El resultado final en mi carpeta Descargas es el cuadro de diálogo que se muestra a continuación:

El nombre de archivo de la ruta que se muestra es, en este momento, el archivo más grande en mi carpeta de descargas con 5,27 GB en el disco.

Nota: El código AppleScript de ejemplo es solo eso y no contiene ningún manejo de errores que pueda ser apropiado. El usuario tiene la responsabilidad de agregar cualquier manejo de errores que sea apropiado, necesario o deseado.