¿Hay alguna manera de mostrar la salida de AppleScript en la barra de menú?

En general, sin un programa de terceros, como Growl, no hay una forma integrada de hacer esto.

Sin embargo, puede escribir un script u otro programa como el que encontré aquí que le proporciona el servicio de menulet. Estoy seguro de que la integración de Growl sería mucho más fácil de lograr.

No hay una forma integrada de hacer esto en OS X. Sin embargo, usando Growl , puedes recibir notificaciones. Aquí hay un script de muestra para eso:

--Make sure Growl is running
tell application "System Events"
    set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
end tell

if isRunning then
    tell application id "com.Growl.GrowlHelperApp"
        set the allNotificationsList to ¬
            {"Test Notification", "Another Test Notification"}
        --Notifications can be enabled in System Preferences>Growl>Applications>Display Options
        set the enabledNotificationsList to ¬
            {"Test Notification"}
        register as application ¬
            "Growl AppleScript Sample" all notifications allNotificationsList ¬
            default notifications enabledNotificationsList ¬
                    -- Set the icon. You can use any icon from any application
            icon of application "AppleScript Editor"

        notify with name ¬
            "Test Notification" title ¬
            "Test Notification" description ¬
            "This is a test AppleScript notification." application name "Growl AppleScript Sample"

        notify with name ¬
            "Another Test Notification" title ¬
            "Another Test Notification :) " description ¬
            "Alas — you won't see me until you enable me..." application name "Growl AppleScript Sample"

    end tell
end if

Eso debería mostrar esto:

Y si también tienes habilitada la otra notificación:

Aquí se describen técnicas más avanzadas .

Dado que AppleScriptObjC es parte de macOS, es posible usar su marco "Fundamento" (incluidos los métodos de NSMenu) para lograr lo que probablemente no fue posible en 2012.

Encontré un script interesante para crear menús personalizados desde AppleScript; de esto extraje el código adecuado para colocar texto en la barra de menú de macOS . De hecho, usa solo el "título" de un menú para insertar algún contenido.

Para demostrar esto, implementé una secuencia de comandos de diálogo muy básica que solicita a los usuarios que ingresen texto (esperando 6 segundos) que luego se muestra en la barra de menú temporalmente (5 segundos).
Aquí lo tienes:

use framework "Foundation"
use framework "AppKit"
use scripting additions
property StatusItem : missing value
property newMenu : class "NSMenu"

display dialog "Write something:" default answer "" giving up after 6
set myText to text returned of the result
if myText is "" then set myText to "TOOOOO slow … try again !"
set myText to ">>    " & myText & "    <<"

set bar to current application's NSStatusBar's systemStatusBar
set StatusItem to bar's statusItemWithLength:-1.0
StatusItem's setTitle:myText
set newMenu to current application's NSMenu's alloc()'s initWithTitle:"Custom"
StatusItem's setMenu:newMenu

delay 5
current application's NSStatusBar's systemStatusBar()'s ¬
        removeStatusItem:StatusItem  

Este código AppleScript se puede usar en cualquier script suyo. (Su parte de "diálogo" es opcional...)

user3439894 ayudó a cerrar mi "menú", vea la última línea del script. ¡Muchas gracias!