¿Hay alguna forma de recibir una notificación emergente en mi iPhone o iPad cuando llegue el correo?

Con el lanzamiento de iOS 5, el correo ahora puede aparecer como una notificación de estilo de cuadro emergente.

Vaya a Configuración> Notificaciones> Correo> y elija "Alertas" en el menú de estilo de alerta.

luego tendrá algo que se parece a una notificación de mensaje cuando llegue un correo electrónico

Dale una oportunidad a BoxCar .

Lo uso de manera similar para las notificaciones de mensajes directos de Twitter.

Uso una combinación de Notify y Prowl , que se ejecuta en una Mac de repuesto. Encontré muchos otros usos para Prowl, como enviar notificaciones automáticas desde un script.

No uses la configuración estándar de Gmail desde iPhone, usa Google Sync.

Aquí: Google Sync: configure su dispositivo Apple para Google SyncCompartir comentario

Esta no es una forma de solucionar su problema ahora, pero creo que iOS 5 podrá hacer lo que quiera cuando se lance este otoño de acuerdo con: http://www.apple.com/ios/ios5/features.html #notificación

Veo capturas de pantalla con notificaciones de correo en la parte superior de la pantalla y creo que se pueden configurar para que sean ventanas emergentes de estilo actual por aplicación.

Uso una combinación de reglas de Apple Mail, un AppleScript y Howl (otra aplicación de gruñido similar a Prowl mencionada anteriormente).

Asigne un nombre a la regla de correo de la siguiente manera: "gruñido-TestPost" como se indica en el AppleScript, luego configure las condiciones y active este AppleScript para que se ejecute. Luego configure su estilo de visualización Growl para usar el de Howl (o Prowl).

Aquí está el AppleScript, lamentablemente no tengo información sobre el guión del autor original que modifiqué:

on run
    -- at current, the registration is done whenever you launch the script, 
    -- and also below whenever the the script itself is run by Mail
    -- (that let's users make new notification on the fly, sort of...)
    -- could probably find a more graceful semaphor, but...
    register()
end run

using terms from application "Mail"
    on perform mail action with messages messageList for rule theRule
        set theRuleName to name of theRule
        if theRuleName does not start with "growl-" then return

        register()
        -- extract notification type from rule name
        set noteType to characters 7 thru (length of theRuleName) of theRuleName as text
        repeat with thisMessage in messageList

            -- basic information for notification
            set theSender to sender of thisMessage
            set theSubject to subject of thisMessage
            set theText to (content of thisMessage)
            set tid to AppleScript's text item delimiters
            set AppleScript's text item delimiters to " "
            try
                set theSummary to (text items 1 through 20 of theText) as text
            on error
                set theSummary to theText
            end try
            set AppleScript's text item delimiters to tid

            -- notify
            tell application "GrowlHelperApp" to notify with name noteType ¬
                title noteType description ¬
                "From: " & theSender & return & "Subject: " & theSubject ¬
                application name "MailGrowl"
        end repeat
        -- if we want to coalesce or order the notifications, then we'd put the 
        -- notifications into an array above and notify GHA here.  I'm not completely
        -- on the structures that are required for grouped messages, though..
    end perform mail action with messages
end using terms from

to register()
    tell application "Mail"
        set ruleList to name of every rule whose name begins with "growl"
    end tell
    set noteTypes to {}
    repeat with theRuleName in ruleList
        set end of noteTypes to (characters 7 thru (length of theRuleName) of theRuleName as text)
    end repeat
    tell application "GrowlHelperApp"
        register as application "MailGrowl" all notifications noteTypes ¬
            default notifications noteTypes ¬
            icon of application "Mail"
    end tell
end register