¿Es posible cambiar el ancho de columna de la vista de lista del Finder en AppleScript?

La respuesta al tema de su pregunta "¿Es posible cambiar el ancho de columna de la Vista de lista del Finder en AppleScript?" Es sí. La respuesta a su pregunta sobre el uso de AppleScript para establecer el ancho de la columna de nombre para que sea lo suficientemente grande como para mostrar los nombres sin truncarlos también es sí. No estoy seguro de cómo manejar las pestañas en la ventana del Finder, pero parece que ya tiene un script que aborda las pestañas.

Una gran sorpresa (para mí) fue que tuve que cerrar y volver a abrir la ventana del Finder para ver el cambio.

Aquí hay una secuencia de comandos que opera en la ventana del Finder que está más al frente. El ancho de la columna "Nombre" se establece en 7,5 * (número de caracteres en el nombre más largo de la ventana). No es el ancho perfecto, pero me funciona siempre que use texto de 12 puntos en el Finder. Estamos configurando el ancho de la columna en una cierta cantidad de píxeles, y cada carácter toma una cantidad diferente de píxeles ya que el Finder no usa una fuente de ancho fijo, por lo que no podemos estar exactamente en lo correcto al configurar el ancho. Pero 7.5 * el número de caracteres en el nombre más largo parece funcionar bastante bien. Puedes ajustarlo, por supuesto.

tell application "Finder"
    activate
    set the_window to window 1
    set current view of the_window to list view
    set the_options to list view options of the_window
    set the_name_column to first column of the_options whose name is name column
    set the_items to name of every item of the_window
    -- get the longest name (count of characters)
    set longest_name to 0
    repeat with I from 1 to count of the_items
        --check for invisible files, which we don't need to consider
        if character 1 of item I of the_items is not "." then
            if (count of characters of item I of the_items) > longest_name then
                set longest_name to count of characters of item I of the_items
            end if
        end if
    end repeat
    -- this only works if the text size is 12. The multiplier 7.5 could be changed
    -- if the text size is something else. 
    set desired_width to longest_name * 7.5
    set width of the_name_column to desired_width
    -- we have to close and reopen the window in order to see any changes.
    -- there might be a "refresh window" command but I don't know it.
    set the_target to target of the_window
    close the_target
    open the_target
end tell

El siguiente código configurará la columna de nombre, en la vista de lista, para que se ajuste al tamaño del nombre de archivo más largo en todas las ventanas abiertas o en todas las pestañas de todas las ventanas de la aplicación Finder. Si no hay ninguna ventana del Finder abierta, se abrirá una nueva ventana del Finder en la vista de lista y establecerá el ancho de la columna del nombre de forma adecuada.

Este código requiere la utilidad de terceros, CLICLIC .

“Cliclick” es la abreviatura de “ C lic en la interfaz de línea de comandos ” . Es una pequeña aplicación de shell/Terminal que emulará los clics del mouse o una serie de clics del mouse (incluidos los clics dobles y los clics de control) en coordenadas de pantalla arbitrarias. Además, le permite mover el mouse, obtener las coordenadas actuales del mouse, presionar teclas modificadoras, etc.

La descarga es gratuita, pero es un software de donación y es fácil de instalar.

En mi sistema tengo cliclicken el siguiente directorio: /usr/local/bin/. Debido a esta ubicación, en mi código AppleScript y en la aplicación Terminal, necesito usar la ruta completa para cliclickllamar al comando. Por ejemplo:  do shell script "/usr/local/bin/cliclick rc:." en AppleScript está diciendo cliclickque haga clic con el botón derecho.

Esto me funciona con la última versión de macOS Mojave.

Las coordenadas xy yutilizadas en este siguiente script se establecieron mientras la resolución de mi pantalla era de 1280 x 800.

global thisWindow

tell application "Finder"
    activate
    if not (exists of Finder window 1) then
        make new Finder window to path to documents folder
    end if
    set theWindows to name of windows
    repeat with i from 1 to count of theWindows
        set thisWindow to item i of theWindows
        set index of Finder window thisWindow to 1
        tell its Finder window thisWindow
            set currentView to current view
            if currentView is not list view then
                set current view to list view
            end if
        end tell
        my setColumnWidth()
    end repeat
end tell

on setColumnWidth()
    tell application "System Events"
        repeat while not (exists of scroll area 1 of splitter group 1 of splitter group 1 ¬
            of window thisWindow of application process "Finder")
            delay 0.1
        end repeat
        set frameBounds to value of attribute "AXFrame" of UI element 2 of row 2 ¬
            of outline 1 of scroll area 1 of splitter group 1 of splitter group 1 ¬
            of window thisWindow of application process "Finder"
    end tell

    set x to (item 1 of frameBounds) - 1
    set y to (item 2 of frameBounds) - 13

    do shell script "/usr/local/bin/cliclick dc:" & x & "," & y -- Double Click At Coordinates
end setColumnWidth