El script de Apple falla al copiar el archivo adjunto de Outlook

El error de parámetro surge porque uno de los parámetros que está enviando al savecomando es erróneo. El fparámetro es el attachmentque se va a guardar, esto está bien.

El problema es el segundo parámetro, que ha indicado que es una POSIX fileruta (una compuesta de barras diagonales, por ejemplo /Users/hitzg/Desktop/some_file.txt).

Sin embargo, la variable saveAsNamese deriva de saveToFolder, que obtiene su ruta de archivo del choose foldercomando. Este comando devuelve una ruta HFS (una compuesta de dos puntos, por ejemplo Macintosh HD:Users:hitzg:Desktop:some_file.txt).

Entonces, la solución es simplemente decidir qué tipo de formato de ruta de archivo va a usar y atenerse a él. Puede O BIEN usar rutas posix y cambiar esta línea del script (abreviado para facilitar la lectura) de esto:

set saveToFolder to (choose folder) as string

a esto:

set saveToFolder to POSIX path of (choose folder)

O use rutas HFS y cambie esta línea del script:

save f in POSIX file saveAsName

a esto:

save f in file saveAsName

Eso corrige su error de parámetro, pero no he probado el resto de su secuencia de comandos para ver cómo funciona. Al leerlo, no hay errores evidentes, por lo que no anticipo ningún otro problema importante.

APÉNDICE

Me gustaría ofrecer algunas modificaciones a su secuencia de comandos original que, en mi opinión, agilizan el código y lo hacen más eficiente y eficaz. Su secuencia de comandos existente es excelente, sin embargo, con el uso estratégico del whosefiltro AppleScript, podemos eliminar el primero de los repeatbucles y mejorar el rendimiento del segundo.

set saveToFolder to (choose folder) as text


tell application "Microsoft Outlook"
    set srcFolder to mail folder "Inbox" of exchange account "FOO"
    
    set selectedMessages to a reference to (messages of srcFolder whose ¬
        class of attachments contains attachment and ¬
        "From: First Last <scanner@some.some>" is in headers)
        
    set attFiles to a reference to attachments of selectedMessages
    set [n, m] to [count selectedMessages, count attFiles]
    
    repeat with f in the attFiles
        set savePath to saveToFolder & name of f
        save f in file savePath
    end repeat
end tell


display alert "" & m & " attachments were saved" message ¬
    "These belonged to " & n & " messages" as ¬
    informational buttons {"OK"} default button 1

El elemento clave de esta versión del script es la implementación del whosefiltro aquí:

    set selectedMessages to a reference to (messages of srcFolder whose ¬
        class of attachments contains attachment and ¬
        "From: First Last <scanner@some.some>" is in headers)

En lugar de buscar en todos los mensajes de su bandeja de entrada los mensajes enviados por un remitente en particular y luego seleccionar los archivos adjuntos, el primer criterio del filtro selecciona instantáneamente solo los mensajes de su bandeja de entrada que tienen archivos adjuntos; los mensajes sin archivos adjuntos son superfluos para nuestras necesidades, por lo que ni siquiera necesitamos considerarlos. El segundo criterio especifica que los correos electrónicos deben provenir de una persona específica, aunque address of senderlamentablemente no se pueden incorporar al filtro, por lo que en su lugar he utilizado los encabezados de los mensajes para asegurarme de que contienen la "From: ..."cadena adecuada.

Para dar formato a esta cadena, simplemente obtenga la headerspropiedad para un mensaje del remitente específico y hojee hasta que encuentre algunas líneas que se vean así:

From: First Last <scanner@some.some>
Subject: Hello World!
Thread-Topic: Hello Again
Thread-Index: AdQD5jaiEJ7GiUlKRYeD5LaN3BaSpA==
Date: Thu, 14 Jun 2018 13:22:53 +0000
Message-ID: <B64BBE7A4C13095094C6A44D85FA3FDB5085651F@ABCD-mail.somemailbox.foo.com>

Estará aproximadamente en el medio del texto del encabezado. Luego, solo asegúrese de que el texto de su filtro coincida con la "From:"línea (copiar y pegar), ya que es casi seguro que será el mismo en todos los correos electrónicos de ese remitente, a menos que haya cambiado su nombre y apellido en algún momento (lo que, por supuesto, puede , estar ausente).

Un filtro un poco más flexible si le preocupa que el nombre y el apellido hayan cambiado con el tiempo, sería simplemente filtrar headerspara ver si contienen solo la dirección de correo electrónico "scanner@some.some". Dado que solo buscará en su bandeja de entrada, es razonable suponer que cualquier aparición de esa dirección de correo electrónico en el encabezado de un mensaje de la bandeja de entrada significa que el correo electrónico se originó en esa dirección o se envió en CC a esa dirección, así como a usted:

    set selectedMessages to a reference to (messages of srcFolder whose ¬
        class of attachments contains attachment and ¬
        "<scanner@some.some>" is in the headers)

El resto del script es más o menos el mismo, con la corrección del error de parámetro implementado.

Habiendo probado el script en mi sistema, funcionó como se esperaba y se desempeñó de manera muy eficiente. El cuello de botella en la velocidad para mí fue tener que descargar cada archivo adjunto para guardarlo, por lo que hubo una consideración de transferencia de datos cuando se ejecutó en mi carpeta de correo de Exchange.

Al ejecutarlo en una carpeta de correo local con archivos adjuntos ya descargados, el guardado de los archivos adjuntos fue prácticamente instantáneo.