Crear un nuevo archivo (.txt) en Finder - Atajo de teclado

Bueno, aquí tienes un AppleScript para eso.

Primero, crea el AppleScript:

1. Automatizador abierto
2. Crear una acción rápida
3. Establecer la entrada a ninguna entrada
4. Arrastre y suelte el elemento de flujo de trabajo Ejecutar AppleScript en el espacio gris.
5. Pegue el código de abajo en el AppleScript
6. Guarde el flujo de trabajo como Crear nuevo archivo
   Si tiene activado iCloud Drive, asegúrese de guardar el archivo Library/Services/en su Carpeta de inicio.

try
  tell application "Finder" to set the this_folder ¬
   to (folder of the front window) as alias
on error -- no open folder windows
  set the this_folder to path to desktop folder as alias
end try

set thefilename to text returned of (display dialog ¬
 "Create file named:" default answer "filename.txt")
set thefullpath to POSIX path of this_folder & thefilename
do shell script "touch \"" & thefullpath & "\""

Para agregarlo como acceso directo:

• Vaya a Preferencias del sistema -> Teclado -> Accesos directos -> Servicios
• Desplácese hacia abajo hasta encontrar el Servicio Crear nuevo archivo
• Asígnele un acceso directo haciendo clic en el lado derecho ninguno , que se convierte en un archivo Add Shortcut.
  Haga clic en el botón y escriba el atajo que desea usar.
  Yo uso ⌘ Command+ ⌥ Option+N

He creado un AppleScript muy similar al de @YoshiBotX, pero con algunas mejoras.

La idea es crear un flujo de trabajo de Automator y asignarle un acceso directo siguiendo los siguientes pasos:

• Abra Automator y cree un Servicio ;
• Establezca la entrada en ninguna entrada y la aplicación en Finder.app ;
• Arrastre y suelte el elemento de flujo de trabajo Ejecutar AppleScript en el espacio gris;
• Coloque el contenido de este AppleScript en el cuadro de texto;
• Guarde el flujo de trabajo con un nombre razonable (como Nuevo archivo );
• Vaya a Configuración -> Teclado -> Accesos directos -> Servicios y asígnele un acceso directo.

Ahora, mostremos el AppleScript:

set file_name to "untitled"
set file_ext to ".txt"
set is_desktop to false

-- get folder path and if we are in desktop (no folder opened)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- no open folder windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- get the new file name (do not override an already existing file)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- create and select the new file
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties {name:new_file}
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- press enter (rename)
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell

Para mayor comodidad, estoy poniendo este AppleScript en este GitHub Gist .

También podría asignar un acceso directo a un script como este:

tell application "Finder"
    set selection to make new file at (get insertion location)
end tell

La ubicación de inserción es el destino de la ventana del Finder que se encuentra más adelante o el escritorio.

Puede crear un servicio de Automator usted mismo; es bastante simple de hacer. Luego, puede asignarle un atajo de teclado para que no necesite activar el servicio a través del menú de servicios (que puede hacer de todos modos).

Abra Automator y seleccione Servicio como el tipo de nuevo documento.

Configure el servicio para que no reciba ninguna entrada en Finder.app y agregue la acción Nuevo documento de edición de texto al flujo de trabajo.

Guarde el servicio, luego abra Preferencias del sistema → Teclado → Accesos directos → Servicios donde encontrará el servicio enumerado en General con el nombre que le dio al servicio cuando lo guardó.

Agregue un atajo de teclado al servicio seleccionando el servicio y luego haciendo clic en 'agregar atajo'.

Aquí puede tener algunos problemas si ya se usa el acceso directo. Así que sea creativo para hacer uno que funcione para usted.

abrir terminal y escribir

touch filename

o

> filename

En los nuevos accesos directos de macOS, puede usar "Ejecutar AppleScript" y el código siguiente. En caso de que ya haya un archivo con el mismo nombre, Accesos directos le mostrará un claro mensaje de error de ejecución que es legible para un usuario final.

on run {input, parameters}
    tell application "Finder"
        set selection to make new file at (get insertion location) with properties {name:"README.txt"}
    end tell
    return input
end run

Este es un repost de un post que hice el año pasado. He tenido una buena experiencia con lo siguiente.

Hay dos utilidades útiles que puede descargar e instalar que le permitirán crear un nuevo archivo de texto (o archivo RTF) en una carpeta actualmente abierta que está viendo usando el Finder.

Las utilidades se denominan NewTextFileHere y NewRTFHere y se pueden descargar desde

http://mac.softpedia.com/developer/Jonas-Wisser-37498.html

Los íconos para cualquiera de estas aplicaciones se pueden incluir en todas las ventanas de Finder.

Justo lo que estaba buscando, Richard Fuhr. Gracias por esto.

Una nota: el enlace de esa URL para NewTextFileHere parece cargarse en una página vacía. Pero hice una búsqueda y encontré la aplicación aquí: http://mac.softpedia.com/progDownload/NewTextFileHere-Download-70374.html

Una alternativa, si ya tienes BetterTouchTools (antes era una aplicación gratuita, ahora tiene un modelo de paga lo que quieras con un período de prueba de 30 días), puedes encontrar la acción en "Utility Actions > Create New File in Current Folder"la que hace exactamente esto, con un ventana emergente que le permite elegir el nombre. Asigne el atajo que desee (seleccioné Opción + Shift + N) y listo.

En caso de que esté utilizando MacVim , hay una opción debajo Finder -> Servicespara crear un nuevo búfer vim:

He asignado esto al atajo ShiftcmdMen System Preferences -> Keyboard -> Shortcuts: