¿Cómo puedo encontrar celdas adyacentes duplicadas en Números?

Tengo una hoja de Números que tiene miles de filas. Como ejemplo en la imagen, la hoja tiene dos columnas con URL. Lo que debo hacer es encontrar las filas que tienen la misma URL en las dos celdas adyacentes y luego cambiar el color de fondo de esa fila para poder identificar las filas y eliminarlas; o escribe la palabra "engañado" en la columna C. En el ejemplo, la fila 4 tiene la misma URL que las dos celdas. ¿Cómo marcaría o marcaría filas como esa en toda la hoja? ¿Con un cálculo? ¿O un Applescript/Automator?

ingrese la descripción de la imagen aquí

Si esto es algo único y basado en la imagen de su pregunta, simplemente insertaría IF(A2=B2,"DUPE","")una nueva fórmula en C2... luego, con C2 seleccionado, presione Comando-C para copiar la fórmula... luego desplácese hacia abajo hasta la última fila que contiene información y presione la tecla Mayús mientras hace clic en la última celda de la columna C para seleccionar el rango y presione Control-C para pegar la fórmula. Ahora, con la columna C que tiene "DUPE" cuando corresponda, ordenaría la hoja en la columna C y resaltaría las filas con "DUPE" en ellas y las eliminaría. Luego seleccione la columna C y presione eliminar para eliminar la fórmula.
Eso debería haber sido Control-V para pegar la fórmula. (Eso es lo que obtengo por copiar y pegar).
Gracias, esto debería funcionar, pero todo lo que obtengo es la fórmula en cada celda de la columna C y no calculan.
Dijiste, "esto debería funcionar, pero todo lo que obtengo es la fórmula en cada celda de la columna C y no calculan". Eso es porque no la estás copiando correctamente, después de usar Números > Insertar > Fórmula > Nueva fórmula y pegar la fórmula en la celda en la que presiona Entrar, luego vuelva a seleccionar la celda en la que pegó la fórmula y luego presione Comando-C para copiar. En otras palabras, la ventana Fórmula no debe estar abierta al realizar la copia después del pegado original.

Respuestas (1)

Aquí hay un método de AppleScript, que demuestra tres tipos diferentes de acciones realizadas en las filas con entradas de celdas duplicadas en columns "A"y "B"(equivalente a cells 1y 2):

use N : application "Numbers"
--------------------------------------------------------------------------------
# PROPERTY VALUES & GLOBAL VARIABLES
property document : a reference to document 1 of N
property sheet : a reference to active sheet of my document
property table : a reference to table 1 of my sheet

global them
--------------------------------------------------------------------------------
# IMPLEMENTATION:
on run
    if not (exists my table) then return false

    set them to a reference to (every row of my table ¬
        where the value of cell 1 = the value of cell 2 ¬
        and the value of cell 1 ≠ missing value)

    highlight()
    ---OR:
    -- comment()
    --OR:
    -- delete -- WARNING: permanent!
end run
--------------------------------------------------------------------------------
# HANDLERS:
to highlight()
    set the background color of them to ¬
        {65535, 65535 / 4, 65535 / 2}
end highlight

to delete
    delete them
end delete

to comment()
    set the value of cell 3 of them to "SNAP!"
end comment
---------------------------------------------------------------------------❮END❯

He definido tres controladores, highlight(), comment()y delete, cada uno de los cuales, si se llama, realizará una acción particular en las filas de interés. Actualmente, puede ver en la secuencia de comandos algunas líneas dentro de la sección etiquetada IMPLEMENTATION:que configuré actualmente para realizar la highlight()acción, lo que cambiará el color de fondo de las filas particulares a un tono de rosa que me gusta.

Debajo de esa línea hay comandos que he comentado usando --, por lo que actualmente permanecen inertes. Cuando no se comenta, el comment()controlador ingresará la palabra "SNAP!"en la tercera columna de cada fila de interés; y el deletecomando (tenga en cuenta la falta de paréntesis para este) simplemente eliminará las filas por completo. He marcado esto con una advertencia que implica la eliminación permanente, aunque en verdad, puede recuperar las filas utilizando el elemento de menú Deshacer⌘Z incorporado de la aplicación, o (¡uno por uno!)

Bonito tono de rosa! :) +1
Gracias, esto funciona muy bien y es un buen ejemplo para trabajar con Números.
¿Cómo puedo encontrar celdas adyacentes duplicadas en Números?
RespuestasAquíPolítica de privacidad1y, 0v