Creo que la clave aquí es: primero debe hacer doble clic en el directorio dentro del cual desea crear la nueva carpeta.

Seleccionar Archivo->Nueva carpeta (o Shift-Command-N) no creará una nueva carpeta en la carpeta actual (o al menos lo que consideraría que es la carpeta actual)

Por ejemplo, en la imagen adjunta, esperaría que "Nueva carpeta" cree una nueva carpeta dentro de la carpeta 1 (seleccionada); en cambio, la creará en la carpeta "Invitado", que era la carpeta abierta originalmente.

Para crearlo en la carpeta 1, primero debe hacer doble clic en la carpeta 1.

Abra la carpeta en la que desea crear una nueva carpeta, luego Archivo > Nueva carpeta o Shift-Command-N.

O

Primero debe hacer doble clic en el directorio dentro del cual desea crear la nueva carpeta. Una vez que esté dentro, haga clic derecho y seleccione "nuevo directorio".

Así es como creo una nueva carpeta en el Finder (vista de lista) solo con el teclado:

1. ↑↓(flechas arriba/abajo) - Resalte la carpeta
2. CommandO- Abrir la carpeta en la misma pestaña
3. CommandShiftN- crear nueva carpeta
4. escriba el nombre de la carpetaEnter
5. CommandOption8- volver a la carpeta anterior (igual que hacer clic en el botón Atrás) Información: El 5. paso es lo mismo que Command[ acceso directo, pero uso el teclado húngaro y para el carácter [ tengo que presionar el Option8combo.

En Windows + Total Commander, solo tuve que presionar F7el botón para crear una nueva carpeta :)

A partir de OSX Catalina,

CommandShiftNCrea una nueva carpeta dentro de la carpeta dentro de la ventana abierta (en su ejemplo, el ~/Downloadsdirectorio). Archivo > Nueva carpeta, el menú contextual y el menú Acciones (engranaje) tienen el mismo comportamiento, independientemente de lo que se seleccione.

Esto es inconsistente con pre-Catalina en mi experiencia. No sé por qué esto cambió. El único método es hacer doble clic en el Picturesdirectorio primero.

El problema es que la vista de lista muestra el contenido de varias carpetas a la vez, pero solo está 'en' la carpeta de nivel superior que aparece en la barra de título. El comando Nueva carpeta se comporta igual que en otras vistas, en aras de la coherencia. (Esa es la opinión de Apple, ya sea que esté de acuerdo o no).

Para aquellos que lo deseen, he creado una acción rápida de Automator muy simple que parece funcionar cuando hace clic con el botón derecho en una carpeta en la vista de lista.

on run {input, parameters}
    
    tell application "Finder"
        
        set thefolder to (input as text)
        
        make new folder at thefolder with properties {name:"New Folder"}
    end tell
    
    return input
end run

No hay una forma integrada de hacerlo en Finder (a partir de macOS 12 Monterey, 2021), pero puede crear una acción de Automator personalizada en su lugar. Esto proporcionará un elemento de menú de clic derecho, así como un atajo de teclado, para crear una carpeta debajo de la carpeta seleccionada en Finder. (Esta respuesta se basa en la excelente respuesta de Benwiggy al agregar un mensaje de diálogo, un atajo de teclado y expandir/seleccionar la nueva carpeta).

Paso 1: Crear el Automator, Acción Rápida

1. Inicio Automatory haga clic en Archivo > Nuevo

2. ElegirQuick Action

3. En el lado derecho, seleccione "El flujo de trabajo recibe corriente: foldersen Finder.app"

4. En el panel izquierdo, seleccione Library > Utilities > Run Applescript. Arrastre Run Applescriptal panel derecho.

5. Copie y pegue el siguiente código:

on run {input, parameters}
    
    set SELECTED_FOLDER to (input as text)
    
    # prompt for new folder name
    set NEW_FOLDER_NAME to text returned of (display dialog "Name of new folder?" buttons {"Cancel", "OK"} default button "OK" default answer "")
    delay 0.1 # prevent UI race conditions
    
    # create new folder 
    tell application "Finder"
        set NEW_FOLDER to make new folder at SELECTED_FOLDER with properties {name:NEW_FOLDER_NAME}
    end tell
    
    # expand new folder 
    tell application "Finder"
        set selection to SELECTED_FOLDER
        activate # need to activate before sending keystroke
    end tell
    tell application "System Events"
        # requires System Preferences > Security & Privacy > Privacy > Accessibility: add Finder.app
        key code 124 # right arrow to expand folder
        delay 0.1 # prevent UI race conditions
    end tell
    
    # select new folder
    tell application "Finder"
        set selection to NEW_FOLDER
    end tell
    
    return input
end run

6. Haga clic en el botón "Hammer" para compilar y obtener resaltado de sintaxis.

7. Archivo > Guardar. Nombra el guión create new folder here.workflowo lo que quieras.

Paso 2: Crea un atajo de teclado

Ahora agregue un atajo de teclado para la acción rápida que acaba de crear:

1. AbiertoPreferences > Keyboard > Services > Files and Folders

2. Debería ver el create new folder hereartículo en la lista.

3. Haz clic Add Shortcuty asigna el atajo de teclado cmd+shift+Mo lo que quieras.

   • Nota: Originalmente quería asignar cmd+shift+opt+Nya que era simplemente optplus cmd+shift+N, el atajo de teclado incorporado para Finder's New Folder. Pero ese atajo no funcionó por alguna razón, solo emitió un pitido. Así que elegí cmd+shift+Mya que estaba al lado cmd+shift+N.

Paso 3: otorgar permiso para enviar pulsaciones de teclas al Finder

Esto es necesario porque expandir la carpeta Finder requiere enviar la right arrowpulsación de tecla, lo que requiere permisos adicionales.

1. AbiertoSystem Preferences > Security & Privacy > Privacy > Accessibility

2. Añadir "Finder.app" ( /System/Library/CoreServices/Finder.app)

3. Asegúrese de Finder.appque esté marcado.

Aquí hay un script que puede usar para esto. Funciona tanto en vistas de lista como de columna. La parte de cambio de nombre no funciona correctamente en las vistas de íconos y galerías, lo que puede ser molesto.

Para usarlo con un atajo, lo exporté como una aplicación desde Script Editor y configuré un atajo para esa aplicación en Butler . Utilicé el atajo estándar del Finder para "Nueva carpeta", ya que no necesito vistas de íconos y galerías, pero es posible que prefiera algo diferente para poder usar el atajo normal. Tenga en cuenta que la aplicación debe tener permisos de accesibilidad (Preferencias del sistema › Seguridad › Confidencialidad).

Es posible que desee ajustar los retrasos a la reactividad de su sistema, ya que pueden ser molestos si está acostumbrado a escribir el nombre de la nueva carpeta rápidamente después de crearla. Sin embargo, si son demasiado bajos, el cambio de nombre no funcionará.

-- By Philippe-André Lorin
-- 2020-12-13
-- macOS 10.14.4
-- See https://apple.stackexchange.com/a/408759/185198

-- Create folder inside currently selected folder
-- or at the same level as currently selected file

try
    tell application "Finder"
        set selectedItems to selection
        set currentPath to ((the first item of the selectedItems) as alias)
        
        -- Set parent path for future new folder
        if (currentPath as string) ends with ":" then
            -- It’s a folder
            set the parentPath to currentPath
        else
            -- It’s a file
            set {savedDelimiters, AppleScript's text item delimiters} to {AppleScript's text item delimiters, ":"}
            set the parentPath to (text items 1 thru -2 of (currentPath as string)) as string
            set AppleScript's text item delimiters to savedDelimiters
        end if
        
        -- Create new folder
        my createFolder(parentPath)
    end tell
    
on error -- No folder or file is selected
    tell application "Finder"
        set the currentPath to (folder of the front window as alias)
        my createFolder(currentPath)
    end tell
end try


on createFolder(folderLocation)
    tell application "Finder"
        -- Make new folder
        set thisFolder to make new folder at folderLocation
        delay 0.2 -- N.B. Without delays, the following operations sometimes fail.
        
        -- Select new folder
        set selection to thisFolder
        delay 0.2
        
        -- Call “Rename” menu in Finder
        activate
        tell application "System Events"
            tell application "System Events"
                tell process "Finder"
                    tell menu bar 1
                        -- N.B. The following must be adjusted to the Finder’s language settings
                        tell menu bar item "File"
                            tell menu "File"
                                click menu item "Rename"
                            end tell
                        end tell
                    end tell
                end tell
            end tell
        end tell
        
        -- Return
        return thisFolder
    end tell
end createFolder

Nota. Este script fue adaptado del primer script de esta página: http://hints.macworld.com/article.php?story=20081119025327978