¿Cómo puedo alternar fácilmente el tamaño del cursor entre normal y más grande?

Estoy usando Mac OS 10.8.3. Tengo una pantalla enorme y mala vista, por lo que me gusta que el cursor del mouse tenga el tamaño más grande posible. (en Preferencias del sistema : Accesibilidad : Pantalla : Tamaño del cursor .

Sin embargo, también realizo una buena cantidad de edición de video, para lo cual uso Final Cut Pro X. Desafortunadamente, los diseñadores de la interfaz de usuario que crearon la interfaz de Final Cut Pro X no tomaron en cuenta adecuadamente los tamaños de cursor más grandes, por lo que cuando hago clic en un botón en la interfaz del programa con la "punta" de un cursor grande, no se registrará. Para remediar esto, cuando uso Final Cut Pro X, cambio el tamaño del cursor a la normalidad.

Sin embargo, hacer esto requiere bastante tiempo, ya que tengo que hacerlo varias veces al día. ¿Hay alguna manera de hacer esto de alguna manera automáticamente?

¿Probaste con otro tipo de cursor?
@Buscar웃 No, estoy usando el cursor predeterminado de OS X.
Esto también es un problema con el cursor de inserción de texto ya que el punto activo no está en la punta, por lo que constantemente tiene que hacer un pequeño ajuste con el cursor grande, y algunas aplicaciones (creo que no son de Cocoa) no muestran la pieza transversal.

Respuestas (4)

Quizás esto sea demasiado excesivo , pero podría crear un AppleScript que alternaría el tamaño del cursor. Para hacerlo solo:

  1. Vaya a Preferencias del sistema/Acceso universal y marque Habilitar acceso para dispositivos de asistencia , esto le permitirá usar AppleScript para consultar y controlar la interfaz de usuario de la mayoría de las aplicaciones.

  2. Vaya a /Aplicaciones/Utilidades/Editor de AppleScript y pegue este código y guárdelo como Aplicación:

    tell application "System Preferences"

    set current pane to pane "com.apple.preference.universalaccess"

    tell application "System Events"

        repeat until slider "Cursor size:" of window "Accessibility" of process "System Preferences" exists
        end repeat

        set theSlider to slider "Cursor size:" of window "Accessibility" of application process "System Preferences"

        set stash to value of theSlider
        if value of theSlider is 1.0 then
            set value of theSlider to 2.2
        else
            set value of theSlider to 1.0
        end if
        stash

    end tell
end tell
No tenía idea de que pudieras hacer esto en AppleScript. En realidad, lo que realmente quería hacer era alternar entre tamaños de cursor, así que actualicé tu respuesta para mostrar cómo hacerlo.
@Mark Puede usar el script para alternar. No es global, pero si lo vincula a una tecla de acceso rápido usando Alfred o una aplicación similar, puede obtener una aproximación bastante cercana.
Probé la secuencia de comandos anterior, pero produce este error: Los eventos del sistema obtuvieron un error: no se puede obtener el grupo 1 de la ventana 1 del proceso de aplicación "Preferencias del sistema". Índice no válido. ¿Alguien sabe qué puedo estar haciendo mal?
@PatrickKenny, mi preferencia es crear un servicio usando Automator y luego configurar el atajo de teclado en las 'Preferencias del sistema' para usar este servicio. Prefiero evitar el software de terceros, como Alfred.
@ user56968 ¿alguna vez lo hiciste funcionar?

Aquí hay una versión actualizada de AppleScript de Thecafremo de 2013 que funciona con Monterey 12.6

tell application "System Preferences" to activate

tell application "System Preferences"
    set current pane to pane "com.apple.preference.universalaccess"
    
    --wait for Accessibility Pane to open - Can go to 0.5 if you are impatient
    delay 1
    
    tell application "System Events"
        
        --Open Vision > Display menu
        select row 5 of table 1 of scroll area 1 of window "Accessibility" of application process "System Preferences" of application "System Events"
        
        --Open Pointer Section menu
        click radio button "Pointer" of tab group 1 of group 1 of window "Accessibility" of application process "System Preferences" of application "System Events"
        
        
        --Change Pointer Size slider
        set theSlider to slider "Pointer size:" of tab group 1 of group 1 of window "Accessibility" of application process "System Preferences"
        
        set stash to value of theSlider
        if value of theSlider is 1.0 then
            set value of theSlider to 4.0 --4.0 is max
        else
            set value of theSlider to 1.0 --1.0 is default
        end if
        
    end tell
end tell
--Uncomment the below to quit sys prefs
--tell application "System Preferences" to quit

La forma más rápida que conozco es Command++ y luego hacer clic en Preferencias para ajustar.OptionF5

Una nota sobre el cursor grande: cambiar el tamaño del cursor no tiene impacto en el enfoque del clic, el punto del cursor permanece igual. Lo que significa que solo ha ampliado su cursor, por lo que el punto de clic activo se ha movido y ya no está exactamente en la punta de la flecha.

En inglés... intente hacer clic no con la punta del cursor grande, sino más adentro.

Te puede gustar el puntero de Mouseposé . Cuesta $ 5 y no tendrá que cambiar de un lado a otro.

Si el mousepoint solo resalta el cursor, entonces es similar al OmniDazzle gratuito, pero hace que encontrar el cursor sea más fácil, pero aún tiene el problema de que el OP pregunta en algunos casos que necesita el cursor más pequeño.
La única razón para un cursor grande es encontrarlo/verlo. La sugerencia para Mousepose es usar un método alternativo en lugar de cambiar y no hace que el cursor original sea más grande. Gracias por la sugerencia "gratis" de Omnidazzle.
Incluso con Omnidazzle o Mouseposé necesitas el cursor grande, esto es de mi propio uso. El programa le permite ver dónde está en la pantalla, pero distrae, para trabajar solo necesita el cursor y debe ser grande para ser visto. Esto podría ser diferente para otros usuarios.

Aquí hay una actualización de mi script anterior reescrito para la configuración del sistema en MacOS Ventura v13.0

Si bien debería ser posible usar un comando de configuración para actualizar el valor del control deslizante, esto no funciona. Mi enfoque es establecer el foco en el control deslizante y luego enviar un comando de teclado (pageup\pagedown) para alternar el cursor entre la configuración máxima y mínima.

tell application "System Settings" to activate

--Open System Settings > Accessibility > Display section
do shell script "open x-apple.systempreferences:com.apple.preference.universalaccess?Seeing_Display"

--Wait for correct pane to load
delay 1

tell application "System Events"
    
    --Get current state of slider 
    set currentState to (get value of slider "Pointer size" of group 2 of scroll area 1 of group 1 of group 2 of splitter group 1 of group 1 of window "Display" of application process "System Settings" of application "System Events")
    
    --Determine key code to send
    if currentState is not greater than 1.0 then
        set keyCode to "116" as integer -- PageUp (increase size)
    else
        set keyCode to "121" as integer -- PageDown (decrease size)
    end if
    
    
    --set focus to slider
    tell slider "Pointer size" of group 2 of scroll area 1 of group 1 of group 2 of splitter group 1 of group 1 of window "Display" of application process "System Settings" to set focused of it to true
    
    delay 0.2
    
    --Send keycode to set size to max or min
    key code keyCode
    
end tell
¿Cómo puedo alternar fácilmente el tamaño del cursor entre normal y más grande?
RespuestasAquíPolítica de privacidad1y, 0v