Con la ayuda de la documentación de Growl sobre la compatibilidad con AppleScript y una pequeña discusión con Bart Arondson y Elliot B en los comentarios sobre la pregunta, se me ocurrió el siguiente AppleScript.

Guardé este script como un agente de aplicación que puede agregar a sus elementos de inicio de sesión en Preferencias del sistema → Usuarios y grupos → Elementos de inicio de sesión .

Básicamente, esta aplicación funciona detectando si se está accediendo a un ejecutable único relacionado con el uso de la cámara. Siempre que se acceda al ejecutable, la aplicación se lo notificará a Growl:

Descargar

Es importante saber que este script monitorea el acceso al ejecutable...

/System/Library/Frameworks/CoreMediaIO.framework/Versions/A/Resources/VDC.plugin/Contents/MacOS/VDC

Guión completo

-- check if growl is running in order to avoid the "Choose Application" dialog
tell application "System Events"
    set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
end tell

-- store time of last iSight access
global lastopened
set lastopened to do shell script "ls -lu /System/Library/Frameworks/CoreMediaIO.framework/Versions/A/Resources/VDC.plugin/Contents/MacOS/VDC | awk '{print $6,$7,$8}'"

-- make the application ready for use with growl
if isRunning then
    tell application id "com.Growl.GrowlHelperApp"

        -- make a list of all the notification types that this script will ever send
        set the allNotificationsList to ¬
            {"iSight access monitor"}

        -- register the script with growl
        register as application ¬
            "iSight access monitor" all notifications allNotificationsList ¬
            default notifications allNotificationsList ¬
            icon of application "FaceTime"

        -- send the first notification right after the application is started
        notify with name ¬
            "iSight access monitor" title ¬
            "iSight access monitor" description ¬
            "last iSight access: 
" & lastopened application name "iSight access monitor"
    end tell
end if

-- monitoring routine: checks every 10s if the VDC executable has been accessed
on idle
    tell application id "com.Growl.GrowlHelperApp"
        set newopen to do shell script "ls -lu /System/Library/Frameworks/CoreMediaIO.framework/Versions/A/Resources/VDC.plugin/Contents/MacOS/VDC | awk '{print $6,$7,$8}'"
        if (newopen is not equal to lastopened) then
            notify with name ¬
                "iSight access monitor" title ¬
                "iSight access monitor" description ¬
                "new iSight access: 
" & newopen application name "iSight access monitor"
            set lastopened to newopen
        end if
    end tell
    return 10 -- interval in seconds
end idle

Micro Snitch hace exactamente lo que estaba buscando:

¿Alguna vez se preguntó si una aplicación graba audio a través del micrófono integrado de su Mac sin su conocimiento? ¿O si la cámara captura video sin una buena razón?

Con Micro Snitch ya no hay dudas. Esta aplicación de barra de menú ultraligera funciona discretamente en segundo plano. Supervisa e informa cualquier actividad de micrófono y cámara para ayudarlo a descubrir si alguien lo está espiando.

No es gratis (4,50 € en el momento de escribir este artículo), pero creo que merece la pena.

_{Sin afiliación, solo un usuario feliz.}