¿Cómo hacer que un enlace se abra en una ventana específica de Safari en macOS?

Esto se puede hacer con una aplicación AppleScript que abre el enlace en Safari y hace que esta aplicación sea el navegador predeterminado.

Encontré dos versiones durante la prueba: abrir en nuevas ventanas o en nuevas pestañas si ya hay una ventana en el espacio actual.

• Abra Script Editor.app (o incluso mejor Script Debugger)

• Si desea que los enlaces se abran en una nueva ventana, use esto

    on open location theURL    
        tell application "Safari"  
            make new document with properties {URL:theURL}  
            activate  
        end tell  
    end open location  

• Si desea que los enlaces se abran en una nueva pestaña (si hay una ventana disponible en el espacio actual), use esto:

    on open location theURL  
        tell application "System Events"  
            tell process "Safari"  
                try  
                    set frontWinName to name of window 1 
                on error  
                    my openNewWindow(theURL)  
                    return  
                end try  
            end tell  
        end tell  

        tell application "Safari"  
            try  
                tell (first window whose name is frontWinName and miniaturized is false)  
                    set current tab to make new tab with properties {URL:theURL}  
                    activate  
                end tell  
            on error  
                my openNewWindow(theURL)  
            end try  
        end tell  
    end open location  


    on openNewWindow(theURL)  
        tell application "Safari"  
            make new document with properties {URL:theURL}  
            activate  
        end tell  
    end openNewWindow  

• Guardar como aplicación

• Si no desea que la aplicación se muestre en el Dock

  • Haga clic derecho en la aplicación, vaya al paquete y busqueInfo.plist

  • Agrega esto enInfo.plist

      <key>LSUIElement</key>  
      <true/>
  

• Configure la aplicación como navegador predeterminado (utilicé RCDefaultApp).

Si quieres ver lo molesto que es el comportamiento del enlace predeterminado de macOS, te sugiero que vuelvas a Safari como navegador predeterminado después de algunas horas...

Todavía estoy en 10.14.6 y no conozco posibles restricciones en Catalina.

Como desarrollador, investigué la posibilidad de que las extensiones pudieran lograr lo que deseas al abrir siempre una nueva ventana al hacer clic en un enlace contenido fuera de Safari. Lamento decir que no creo que este enfoque sea posible.

Desafortunadamente, Safari no brinda a las extensiones una forma de determinar el origen de una nueva pestaña/ventana. Lo que quiero decir con esto es que se puede crear una nueva pestaña porque el usuario hace clic en un enlace en un correo electrónico, hace clic con el botón Comando en un enlace en Safari, abre un marcador de Safari mientras mantiene presionado Comando, hace clic en un enlace dentro de un documento PDF o cualquier una de varias otras acciones que abrirán una página en una nueva pestaña. Independientemente del método, Safari no proporciona cómo se abrió la ventana a una extensión de Safari.

Dado que todos estos eventos tienen el mismo aspecto, ninguna extensión puede obligar a los enlaces desde fuera de Safari a abrirse en ventanas nuevas sin afectar también a los enlaces abiertos de otras formas (incluso al navegar dentro de Safari).

Aunque no se abre de forma nativa en la ventana deseada, siempre puede tomar la pestaña y cambiarla de posición en otra ventana de safari directamente después de que se haya abierto.

No estoy seguro si esto ayuda o no, solo una sugerencia.