¿Cómo edito la EEPROM de un sensor de CO2 K30?

EDITAR: el código corregido se encuentra en la parte inferior del OP.

Fondo

Mientras trabajaba en un circuito para registrar el dióxido de carbono con un sensor de CO2 K30 usando un escudo de registro de datos de Adafruit , me encontré con un problema. La dirección I2C del RTC en el escudo tiene una colisión con la dirección del sensor de CO2. La dirección del RTC está integrada en el silicio y no se puede cambiar , pero la dirección del sensor K30 es mutable . De acuerdo con la guía I2C ( consulte el PDF en I2C/I2C_comm_guide , ¡advertencia en PDF comprimido!), la dirección I2C del sensor puede tener cualquier valor:

0x00 a 0x7F

Precedente

Esto parece ser un problema común. He encontrado varios hilos (ver a , b , c , d , e , f ) que han intentado resolver este desafío. La mayoría fracasa con los resultados positivos o sugiere usar una interfaz diferente. SIN EMBARGO, según la hoja de datos, debería ser posible piratear este cambio en la EEPROM.

Soluciones alternativas que estoy evitando

• K30 RX/TX: dado que el K30 tiene pines I2C y RX/TX, ¿por qué no cambiar a RX/TX y omitir todo este lío? El sensor está montado en una placa de conexiones con muchas otras partes y un escudo protector adherido con resina epóxica. Me gustaría evitar excavar en el hardware para llegar a estos pines.
• Software GasLab: el fabricante proporciona el software GasLab para piratear los sensores mediante una GUI a través de USB. Desafortunadamente, solo funciona para Windows.
• Elija un RTC diferente: necesito algo rápido y fácil para registrar valores ya que tengo poco tiempo. No quiero reinventar la rueda cuando el escudo de Adafruit funciona tan bien.
• Dirección 0x7F: según la hoja de datos, debería poder llamar a todos los sensores K30 usando esta dirección, sin embargo, no pude hacer que funcionara en la práctica cuando estaba en el mismo circuito que el RTC.

Mi hardware

Estoy ejecutando un clon de Arduino Uno conectando el I2C a A4 y A5. Las líneas I2C tienen pullups de 2.2K. El K30 está funcionando a ~9V.

Prueba de cordura

Al ejecutar el código Arduino proporcionado por el fabricante, puedo leer la respuesta del sensor y tiene sentido.

Codigo para cambiar EEPROM

#include <Wire.h>

byte CheckSum(byte * buf, byte count) {
    byte sum=0;
    while (count>0) {
        sum += *buf;
        buf++;
        count--;
    }
    return sum;
}

void setup() {
    Serial.begin(9600);
    Wire.begin();
    delay(1000);

    byte changebuf[4] = {0x31, 0x00, 0x69, 0x00};
    changebuf[3] = CheckSum(changebuf, 3);
    
    Wire.beginTransmission(0x68<<1);
    for (size_t i = 0; i<sizeof(changebuf); i++) {
        Wire.write(changebuf[i]);
    }
    Wire.endTransmission();
}

void loop() {}

El mensaje 0xD0, 0x31, 0x00, 0x69, 0x9Aes Los bytes son:

1. La dirección predeterminada se desplazó a la izquierda en uno (también probé simple 0x68)
2. Comando para escribir 1 byte en EEPROM
3. Dirección en EEPROM a escribir
4. Carga útil para escribir
5. Suma de verificación

Estos valores se basan en la hoja de datos.

Después de ejecutar esto, enciendo y enciendo el dispositivo para que los valores de EEPROM se propaguen a la RAM según la hoja de datos.

Observaciones

Después de ejecutar el código anterior, la dirección no cambia. El dispositivo sigue respondiendo a la dirección predeterminada original 0x68y no responde a la nueva dirección 0x69.

La pregunta replanteada

¿Por qué está fallando mi intento de ordenar a la EEPROM del K30 que cambie el valor asociado con la dirección I2C del dispositivo? ¿Hay algún problema con la secuencia de bytes que envío?

SOLUCIÓN: según la solución aceptada, me perdí el LSB adicional obvio en la cadena de bytes. Ahora puedo cambiar la dirección. Aquí está el código completo corregido para lograr esto:

#include <Wire.h>

byte CheckSum(byte * buf, byte count) {
    byte sum=0;
    while (count>0) {
        sum += *buf;
        buf++;
        count--;
    }
    return sum;
}

void setup() {
    Serial.begin(9600);
    Wire.begin();
    delay(1000);

    byte changebuf[5] = {0x31, 0x00, 0x00, 0x69, 0x00};
    changebuf[4] = CheckSum(changebuf, 4);
    
    Wire.beginTransmission(0x68);
    for (size_t i = 0; i<sizeof(changebuf); i++) {
        Wire.write(changebuf[i]);
    }
    Wire.endTransmission();
}

void loop() {}