¿Cómo cambiar la posición de la barra de desplazamiento en AppleScript?

Puede usar JavaScript para establecer la cantidad de desplazamiento.

Para ajustar el desplazamiento con un porcentaje definido:

set myURL to "https://weather.com/weather/hourbyhour/l/12345"
set scrollAmount to "16" --- % down the page

tell application "Google Chrome"
    activate
    tell front window to set curTab to make new tab at after (get active tab) with properties {URL:myURL}
    tell curTab
        repeat while (loading)
            delay 1
        end repeat
        -- set the vertical scroll 
        execute javascript "h=document.documentElement.scrollHeight-document.documentElement.clientHeight; window.scrollTo(0,h*" & scrollAmount & "/100)"
    end tell
end tell

Para ajustar el desplazamiento vertical en la parte superior de un elemento de la página, el script puede obtener el elemento con document.getElementById('twc-scrollabe') twc-scrollabe como identificador de la tabla.

Después de eso, JavaScript usa un bucle para obtener la parte superior de la tabla en la página.

set myURL to "https://weather.com/weather/hourbyhour/l/12345"
tell application "Google Chrome"
    activate
    tell front window to set curTab to make new tab at after (get active tab) with properties {URL:myURL}
    tell curTab
        repeat while (loading)
            delay 1
        end repeat
        -- scroll to the top of the table
        execute javascript "e=document.getElementById('twc-scrollabe');tTop=0; do {tTop +=e.offsetTop || 0; e=e.offsetParent} while(e); window.scrollTo(0,tTop);"
    end tell
end tell

El problema con este JavaScript (en otra URL), debes encontrar el identificador en la fuente de la página y cambiarlo en el script, si el elemento no tiene identificador, debes usar otros métodos para obtener el elemento, el JavasScript el código será diferente dependiendo de la página del sitio.

Según la información adicional que proporcionó en los comentarios, permítame ofrecerle el siguiente código de ejemplo de cómo lo haría. (Al menos hasta que aprendí una mejor manera).

set myURL to "https://weather.com/weather/hourbyhour/l/12345"

tell application "Google Chrome"
    set bounds of front window to {0, 23, 1440, 850}
    tell front window to make new tab at after (get active tab) with properties {URL:myURL}
    repeat while (loading of active tab of front window is true)
        delay 1
    end repeat
    activate
    tell application "System Events"
        repeat 9 times
            key code 125 -- # Down Arrow
            delay 0.1
        end repeat
    end tell
end tell

Notas:

• El valor del delay comando en el repeat while ... bucle se puede ajustar a algo más o menos, según lo considere adecuado, en función de la rapidez con la que se cargue realmente esa página, querrá minimizar la cantidad de veces que se activa el evento solo para que no se sobrecargue innecesariamente. desencadenar el evento . Es necesario que la página termine de cargarse, de lo contrario, el siguiente repeat ciclo no se desplazará la cantidad adecuada. (Obviamente estoy usando el término pergamino en sentido figurado).

• En la tell application "System Events" declaración/bloque , es posible que deba ajustar la cantidad de veces que se activa el repeat bucle . El delay comando en este repeat bucle es necesario, de lo contrario, el key code evento , en este caso de uso, no se registra en la página correctamente.