Actualización:
después de las dos respuestas hasta ahora, he movido ligeramente los postes de la portería. Necesito múltiples selecciones y pestañas: las respuestas existentes; uno tiene la capacidad de selección múltiple, el otro me da pestañas, lo que me he dado cuenta es el camino a seguir.
Decidí que la mejor manera de realizar un seguimiento de un catálogo de fotografías publicadas sin alterar su jerarquía original era arrastrar los alias a una ubicación separada.
Sin embargo, muchos casos de uso requieren el original; no pueden hacer frente a que el alias se coloque en, por ejemplo, un sitio web o Photos.app
Clic derecho: Mostrar original insiste en mostrarlo dentro del mismo contenedor de ventana, por lo que volver a la carpeta de alias pierde su lugar, la selección desaparece. En una carpeta grande, esto realmente pone a prueba tu memoria en cuanto a dónde estabas.
¿Hay alguna forma de forzarlo a que se abra en una nueva ventana, similar a Cmd/doble clic en una carpeta, manteniendo así su lugar en la carpeta de alias?
Actualmente en High Sierra 10.13.4
Miré a mi alrededor y encontré un applescript (que se puede convertir en un atajo) que solo quiere que tú quieras. Desafortunadamente, no es tan simple como debería ser. Sin embargo, es mejor que nada, y solo necesita hacer esto una vez. Le ahorrará tiempo a largo plazo.
1) Automatizador abierto.
2) Crear nuevo 'Servicio'
3) Establezca el servicio recibido en 'sin entrada' en 'Finder'
4) agregue 'Ejecutar applescript'
5) poner este código dentro de él:
-- duplicateFinderTab.scpt
-- Uses a hacky workaroud to duplicate the frontmost Finder tab,
-- since Apple hasn't provided great AppleScript support for this.
----------------------------------------------
on run {}
tell application "Finder"
if (count of Finder windows) > 0 then set duplicate_me to target of front Finder window
set _sel to the selection
end tell
new_tab()
tell application "Finder"
set target of front Finder window to duplicate_me
select _sel
end tell
open_orig()
end run
----------------------------------------------
on new_tab()
tell application "System Events" to tell application process "Finder"
set frontmost to true
tell front menu bar to tell menu "File" to tell menu item "New Tab"
perform action "AXPress"
end tell
end tell
end new_tab
----------------------------------------------
on open_orig()
tell application "System Events" to tell application process "Finder"
set frontmost to true
tell front menu bar to tell menu "File" to tell menu item "Show Original"
perform action "AXPress"
end tell
end tell
end open_orig
6) guárdelo (si abre una ventana del buscador y tiene su alias seleccionado, luego regrese a Automator y presione 'ejecutar', luego funcionará en este punto) - Nota: puede solicitarle que agregue 'Automator' a los permisos 'Preferencias del sistema' -> 'Seguridad y privacidad' -> 'Accesibilidad'.
7) en las preferencias del sistema, vaya a 'teclado' -> 'accesos directos' -> 'servicios' -> 'como sea que lo haya llamado' ... elija un acceso directo (como "^-CMD-O").
Otras cosas:
Puede requerir que hagas esto una vez:
cuando se selecciona el buscador, en el menú,
'Finder' -> 'Servicios' -> 'como sea que lo llames'
o si no apareciera:
'Buscador' -> 'Servicios' -> 'Preferencias de servicios...' -> marque la casilla en las preferencias del sistema a la que se llama su aplicación
Hay otros errores de permiso que puede recibir dependiendo de cómo esté configurado su sistema, sin embargo, debe notar que el script SÍ funciona cuando presiona 'ejecutar' en el paso 6 o después del paso 5. Primero seleccione el archivo en el buscador y luego cambie a la aplicación de automatización y presione 'ejecutar'.
Y si todo funcionó sin problemas para usted, el acceso directo cmd-cntl-O debería funcionar para usted, por lo que puede hacer ese acceso directo (que abre una nueva pestaña de la misma selección), luego haga clic con el botón derecho y seleccione 'mostrar original'
Editar por OP
Si recibe un error "com.automator.runner.xpc no tiene acceso de asistencia permitido", entonces la solución no es obvia.
No puede agregar com.automator.runner.xpc en sí mismo a Assistive Access, ni agregar Automator o Automator Runner ayuda, sin embargo, después de reiniciar, la pista fue que se activaron dos errores, no solo uno.
Agregar Finder en sí mismo a Assistive Access permitió que se ejecutara el script.
Una solución mucho más corta y limpia sin secuencias de comandos de interfaz de usuario:
Abra Automator, cree un nuevo Servicio, acepte archivos y carpetas del Finder, agregue una acción Ejecutar AppleScript y escriba lo siguiente:
on run {input, parameters}
repeat with aFile in input
tell application "Finder"
try
set origFile to original item of aFile
set aWindow to make new Finder window
set aWindow's target to origFile's parent
select origFile
end try
end tell
end repeat
end run
Su pantalla debería verse algo como esto:
Guarde el servicio de Automator como Revelar en una ventana nueva y, a continuación, abra Preferencias del sistema/Teclado/Accesos directos/Servicios . Busque el servicio Mostrar en ventana nueva , haga clic en Agregar acceso directo y escriba ⌥⌘R. Su pantalla debería verse algo como esto:
Cierra y prueba el servicio en Finder seleccionando uno o más alias y presionando el atajo elegido ⌥⌘R. Funciona con múltiples archivos, carpetas y puede realizar la Revelación incluso si algunos de los elementos no son en realidad alias (de ahí el intento/finalización del script).
set aWindow to make new Finder window
para abrir una nueva pestaña en su lugar?Con la ayuda de StackOverflow y a partir de las ideas presentadas en ambas respuestas de brw59 boris42 , ahora tengo esto, por user3439894
on run {input, parameters}
set madeNewWindow to false
repeat with i from 1 to count input
tell application "Finder"
if (kind of item i of input) is equal to "Alias" then
set origFile to original item of item i of input
if not madeNewWindow then
set aWindow to make new Finder window
set madeNewWindow to true
else
my makeNewTab()
end if
set aWindow's target to origFile's parent
select origFile
end if
end tell
end repeat
end run
on makeNewTab()
tell application "System Events" to tell application process "Finder"
set frontmost to true
tell front menu bar to tell menu "File" to tell menu item "New Tab"
perform action "AXPress"
end tell
end tell
end makeNewTab
Combina lo que pensé que necesitaba con lo que realmente necesitaba, utilizando secuencias de comandos de interfaz de usuario y no relacionadas con la interfaz de usuario y me presenta una nueva ventana, muy bien llena de pestañas, todas con un alias seleccionado, para que pueda hojear las pestañas y lidiar con cada selección una a la vez, luego cerrar después, dejando mi ventana original en su lugar.
boris42
Tetsujin
boris42
Tetsujin
Tetsujin